justifiy question

August 16, 2007, 11:10 AM

jackyzsn

 
Hi,

I want to display the following heading line:

"FOR THE PERIOD: <E13 TO <E14   DATE: &DATETRMDYY   TIME: &TOD  "

for 'FOR THE PERIOD: <E13 TO <E14' I want it to appear at the left, and 'DATE: &DATETRMDYY   TIME: &TOD' appear at the right. 
And they are in the same row..

August 16, 2007, 11:16 AM

Leah

  QUOTE]"FOR THE PERIOD: <E13 TO <E14  <60> DATE: &DATETRMDYY   TIME: &TOD  "

for 'FOR THE PERIOD: <E13 TO <E14' I want it to appear at the left, and 'DATE: &DATETRMDYY   TIME: &TOD' appear at the right. 
And they are in the same row..[/QUOTE]

[

You could try a posistioning marker, Haven't found any other option. I inserted it in the quote. Of course this doesn't work for html output very well.

August 20, 2007, 05:31 PM

Francis Mariani

You could make the two pieces DEFINEd columns and then use style-sheet commands to align them left and right using HEADALIGN=BODY, and COLSPAN...

August 21, 2007, 03:07 AM

Tony A

As Leah says, spot markers are a possible method. The following works for both HTML and PDF -

DEFINE FILE CAR
  E13/DMYY = '01022007';
  E14/DMYY = '28022007';
END
TABLE FILE CAR
SUM RCOST DCOST
BY COUNTRY BY CAR BY MODEL BY BODYTYPE
IF RECORDLIMIT EQ 1
ON TABLE PCHOLD FORMAT HTML
HEADING
"FOR THE PERIOD: <E13 TO <E14 <+0 DATE: &DATETRMDYY TIME: &TOD"
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET STYLE *
  UNITS=IN, PAGESIZE='A4', LEFTMARGIN=0.20, RIGHTMARGIN=0.20, TOPMARGIN=0.20,
  BOTTOMMARGIN=0.20, SQUEEZE=ON, ORIENTATION=PORTRAIT, BACKCOLOR=RGB(240 245 255), $
TYPE=HEADING, BORDER=LIGHT, BORDER-STYLE=SOLID, SIZE=8, BACKCOLOR='WHITE', STYLE=BOLD, $
-* In this particular case .......
-* Item 1 is everything before the first carat "<"
TYPE=HEADING, LINE=1, ITEM=1, WIDTH=1.10, JUSTIFY=LEFT, STYLE=BOLD, $
-* Item 2 is the field E13
TYPE=HEADING, LINE=1, ITEM=2, WIDTH=0.60, JUSTIFY=CENTER, STYLE=BOLD, $
-* Item 3 is everything upto the next carat
TYPE=HEADING, LINE=1, ITEM=3, WIDTH=0.20, JUSTIFY=CENTER, STYLE=BOLD, $
-* Item 4 is the field E14
TYPE=HEADING, LINE=1, ITEM=4, WIDTH=0.60, JUSTIFY=CENTER, STYLE=BOLD, $
-* Item 5 is the "<+0" place marker
TYPE=HEADING, LINE=1, ITEM=5, WIDTH=2.45, $
TYPE=HEADING, LINE=1, ITEM=6, WIDTH=2.60, JUSTIFY=RIGHT, STYLE=BOLD, $
ENDSTYLE
END
-RUN

Just play around with the WIDTH values to suit your needs. Also look at using WRAP and SQUEEZE etc.

T

August 21, 2007, 09:40 AM

jackyzsn

I want to generate it in HTML, don't want to limit to fixed with..
HEADALIGN=BODY and COLSPAN not sure how to do because my heading has two lines. I look at the HTML code it generates:

  
<BODY>
<TABLE BORDER CELLPADDING=1>
<TR>
<TD COLSPAN=10>
<TABLE CELLPADDING=0 WIDTH="100%"><TR>
<TD>
PAGE     1</TD></TR></TABLE></TD>
</TR>
<TR><TD COLSPAN=10>
<TABLE BORDER=0 CELLSPACING=0 CELLPADDING=0 WIDTH="100%">
<TR>
<TD ALIGN=CENTER>
<B><I><FONT SIZE=7>CI Payout Adhoc Report </FONT></I></B></TD>
</TR>
<TR>
<TD>
 </TD>
</TR>
<TR>
<TD>
FOR THE PERIOD: 2001/01/01 TO 2008/01/01 DATE: AUGUST 21, 2007      TIME: 09.26.04</TD>
</TR>
</TABLE></TD></TR>
<TR>

All elements are in one table cell, if it can generate like below, put two parts into two different cells, that will display correctly but I guess it will be tough

  
<BODY>
<TABLE BORDER CELLPADDING=1>
<TR>
<TD COLSPAN=10>
<TABLE CELLPADDING=0 WIDTH="100%"><TR>
<TD>
PAGE     1</TD></TR></TABLE></TD>
</TR>
<TR><TD COLSPAN=10>
<TABLE BORDER=0 CELLSPACING=0 CELLPADDING=0 WIDTH="100%">
<TR>
<TD ALIGN=CENTER>
<B><I><FONT SIZE=7>CI Payout Adhoc Report </FONT></I></B></TD>
</TR>
<TR>
<TD>
 </TD>
</TR>
<TR>
<TD>
FOR THE PERIOD: 2001/01/01 TO 2008/01/01</TD>
<TD ALIGN=RIGHT>
DATE: AUGUST 21, 2007      TIME: 09.26.04</TD>
</TR>
</TABLE></TD></TR>
<TR>

August 21, 2007, 10:07 AM

Francis Mariani

One way to align pieces of a heading line:

-SET &ECHO=ALL;

DEFINE FILE CAR
E13/A8DMYY = '01022007';
E14/A8DMYY = '28022007';
E13F/A17 = CHGDAT('DMYY', 'MDYYX', E13, 'A17');
E14F/A17 = CHGDAT('DMYY', 'MDYYX', E14, 'A17');

HEAD1A/A54 = 'FOR THE PERIOD: ' | E13F | ' TO ' | E14F;
HEAD1B/A50 = 'DATE: ' | '&DATETRMDYY' | ' TIME: ' | '&TOD';
END
-RUN

TABLE FILE CAR
SUM 
RCOST 
DCOST
BY COUNTRY 
BY CAR 
BY MODEL 
BY BODYTYPE

IF RECORDLIMIT EQ 1

ON TABLE PCHOLD FORMAT HTML

HEADING
"<HEAD1A<HEAD1B"
"Heading Line 2"

ON TABLE SET PAGE NOLEAD
ON TABLE SET HTMLCSS ON

ON TABLE SET STYLE *
FONT='ARIAL', SIZE=8, $

TYPE=HEADING, HEADALIGN=BODY, $
TYPE=HEADING, LINE=1, ITEM=1, COLSPAN=3, JUSTIFY=LEFT, $
TYPE=HEADING, LINE=1, ITEM=2, COLSPAN=3, JUSTIFY=RIGHT, $
TYPE=HEADING, LINE=2, COLSPAN=99, $
ENDSTYLE
END
-RUN

In FOCUS since 1986	WebFOCUS Server 8.2.01M, thru 8.2.07 on Windows Svr 2008 R2
	WebFOCUS App Studio 8.2.06 standalone on Windows 10