I have a report that totals payments made across the year in which they were paid by a variety of categorizations. We are now passing the 10 year mark of payments and the report is now too large for printing in landscape mode.

Is there a way to split the report into two pages using some sort of pagebreak method on the across field?

I have tried,
ON YEARFIELD PAGE-BREAK WHEN YEARFIELD EQ '2006'

with no luck. Am I missing an easy method for this or am I gonna have to get tricky?

Thanks in advance!!!

This message has been edited. Last edited by: Kerry,

Can you use the SET PANEL and SET BYPANEL settings to move some columns to another page?

Yup. The BYPANEL setting is what you need. This allows you to specify the BY columns that should appear at the left of the page whenever a report is panelled. More or less or horizontal page break.

Thanks... I needed that...

Yeees... but this is valid only with PDF output.

Also, if you have a BY field, remember that you might also want to use BYPANEL in order to replicate the BY fields on each PANEL

Close... But no cigar (in my case)... What can we do to get this to work with COMPOUND NOBREAK reports. "ON TABLE PCHOLD FORMAT PDF OPEN NOBREAK" for my first report it's the NOBREAK that causes the issue... "ON TABLE PCHOLD FORMAT PDF" for reports 2 through X, "ON TABLE PCHOLD FORMAT PDF CLOSE" on my last report... Each report consists of

TABLE FILE CAR
SUM DCOST RCOST UNITS MPG RPM
BY MODEL
ACROSS MODEL
ON TABLE PCHOLD FORMAT PDF [OPEN NOBREAK | nothing | CLOSE]
END
-RUN

I get the following

NUMBER OF RECORDS IN TABLE=       18  LINES=     18
 (FOC3218) NOTE: REPORT WILL BE PANELED; TOTAL WIDTH IS: 132.25 INCHES
 (FOC3269) PDF: CANNOT USE NOBREAK WITH PANELED REPORTS
 (FOC3298) ERROR FOUND IN A COMPOUND REPORT
 Compound Report is TERMINATING.....

I am assuming that this does not work with HTML output?

Is there a way to do this with HTML?

quote:

FOC3269) PDF: CANNOT USE NOBREAK WITH PANELED REPORTS

That will be a problem. If the reports are so wide that they must panel then you're kind of out of luck.

I don't know if the new layout tool and compound report syntax will help you out any ( they don't use the OPEN/CLOSE/NOBREAK syntax) but that may be your only option. Possible creating one report with the first panel's data and one with the second panel's data and then using the correlation functionality available with the new compound report syntax.

quote:

Is there a way to do this with HTML?

There's no such thing as panelling when output is HTML, so I'm not sure how your question applies.

Just a thought, though, I'm sure the business data/logic is not as simple as CENTORD:

  
DEFINE FILE CENTORD
  NEW_ORDER/YYM = ORDER_DATE;
  NEW_YEAR/YY   = ORDER_DATE;
END
TABLE FILE CENTORD
SUM
    QUANTITY
	  COMPUTE CNTR/I5 = IF NEW_YEAR EQ LAST NEW_YEAR THEN CNTR ELSE CNTR + 1;
BY NEW_YEAR
BY NEW_ORDER
BY PLANT
WHERE ORDER_DATE FROM '20010108' TO '20090114';
  ON TABLE HOLD AS GET_DATA
END
-RUN
TABLE FILE GET_DATA
SUM
    MAX.CNTR
 ON TABLE SAVE
END
-RUN
-READ SAVE &CNTR.I5.
-SET &PASSES = &CNTR;
-SET &XCNTR = 1;
-REPEAT DO_REPORT &PASSES TIMES
-SET &OPEN_CLOSE = IF &XCNTR EQ 1       THEN 'OPEN'
-             ELSE IF &XCNTR EQ &PASSES THEN 'CLOSE' ELSE ' ';
TABLE FILE GET_DATA
SUM
   QUANTITY
 BY PLANT
ACROSS NEW_ORDER
WHERE CNTR EQ &XCNTR;
  ON TABLE PCHOLD FORMAT PDF &OPEN_CLOSE NOBREAK
ON TABLE SET STYLE *
     UNITS=CM,
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT, SQUEEZE=ON, FONT='ARIAL', SIZE=7, $
ENDSTYLE

END
-RUN
-SET &XCNTR = &XCNTR + 1;
-DO_REPORT
-EXIT

quote:

I don't know if the new layout tool and compound report syntax will help you out any

Unfortunatly: No. the "tool" truncates reports that extend past the right margin (as per the doc). We (thanks to Anubha) have performed programatic paneling for the PDF output. But, that's a lot of hard-to-maintain code to do something that I think (imho) should be handled in COMPOUND... I'll wait and watch it happen ... someday...