I'm trying to bring the borders, for the subfoot lines in HTML report. but the border option is not working for html report.... also need to check for EXL2k reports...
how to get the subfoot borders in HTML and EXL2K FORMATS
TABLE FILE CAR
SUM DEALER_COST NOPRINT RETAIL_COST NOPRINT CNT.CAR NOPRINT
COMPUTE CNTR/I8 = C2/C3; NOPRINT
BY COUNTRY
SUM DEALER_COST RETAIL_COST
BY COUNTRY
BY CAR
ON COUNTRY SUBFOOT
"<+0> <+0> <+0> <+0><CNTR"
"<+0> <+0> <+0><DEALER_COST<+0><RETAIL_COST"
ON TABLE SET HTMLCSS ON
-*ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT,
HEADALIGN=BODY,
BORDER=LIGHT,
BACKCOLOR=GRAY,
$
TYPE=SUBFOOT,
HEADALIGN=BODY,BORDER=LIGHT,BORDER-TOP-COLOR=BLACK,BORDER-BOTTOM-COLOR=BLACK,
LINE=1,ITEM=4,COLOR=RED,
$
ENDSTYLE
END
This message has been edited. Last edited by: Kerry,
WebFOCUS 7.6.10 Windows Output: Excel,PDF
November 30, 2011, 11:18 AM
ERINP
subbu, The following code allows for a border around the SubFoot. You may have to play with the positioning of the subfoot data.
TABLE FILE CAR
SUM
'CAR.BODY.DEALER_COST' NOPRINT
'CAR.BODY.RETAIL_COST' NOPRINT
'CNT.CAR.COMP.CAR' NOPRINT
COMPUTE CNTR/I8 = C2 / C3; NOPRINT
BY 'CAR.ORIGIN.COUNTRY'
SUM
'CAR.BODY.DEALER_COST'
'CAR.BODY.RETAIL_COST'
BY 'CAR.ORIGIN.COUNTRY'
BY 'CAR.COMP.CAR'
ON CAR.ORIGIN.COUNTRY SUBFOOT
"<+0> <+0> <+0> <CNTR"
"<+0> <+0> <DEALER_COST<RETAIL_COST"
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
FONT='TIMES NEW ROMAN',
SIZE=10,
HEADALIGN=BODY,
$
TYPE=SUBFOOT,
BY=1,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=LIGHT,
BORDER-RIGHT=LIGHT,
HEADALIGN=BODY,
JUSTIFY=RIGHT,
$
ENDSTYLE
END
This message has been edited. Last edited by: ERINP,
WebFOCUS 7.6.9
Reporting client Windows 2003 Service pack 2 using IIS and TomCat 5.5 Reporting Server OS/400 V5R4M0 Outputs: HTML, Excel, PDF, CSV, and Flat Files
November 30, 2011, 11:45 AM
subbu
Hi ERINP,
Thanks for the information, but I need a border between the two subfoot text, here "AVG" and "SubTotal"
TABLE FILE CAR
SUM
'CAR.BODY.DEALER_COST' NOPRINT
'CAR.BODY.RETAIL_COST' NOPRINT
'CNT.CAR.COMP.CAR' NOPRINT
COMPUTE CNTR/I8 = C2 / C3; NOPRINT
BY 'CAR.ORIGIN.COUNTRY'
SUM
'CAR.BODY.DEALER_COST'
'CAR.BODY.RETAIL_COST'
BY 'CAR.ORIGIN.COUNTRY'
BY 'CAR.COMP.CAR'
ON CAR.ORIGIN.COUNTRY SUBFOOT
"<+0> <+0> <+0> <CNTR"
"<+0> <+0> <DEALER_COST<RETAIL_COST"
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
BORDER=LIGHT,
$
TYPE=REPORT,
FONT='TIMES NEW ROMAN',
SIZE=10,
HEADALIGN=BODY,
$
TYPE=SUBFOOT,
BY=1,
BORDER-TOP=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-LEFT=LIGHT,
BORDER-RIGHT=LIGHT,
HEADALIGN=BODY,
JUSTIFY=RIGHT,
$
ENDSTYLE
END
WebFOCUS 7.6.10 Windows Output: Excel,PDF
November 30, 2011, 11:51 AM
ERINP
subbu, So you want a border between LINE=1 and LINE=2 of your subfoot??
ERINP
WebFOCUS 7.6.9
Reporting client Windows 2003 Service pack 2 using IIS and TomCat 5.5 Reporting Server OS/400 V5R4M0 Outputs: HTML, Excel, PDF, CSV, and Flat Files
November 30, 2011, 12:12 PM
subbu
Hi,
Yes exactly I want the border between LINE1 AND LINE2 of the subfoot
WebFOCUS 7.6.10 Windows Output: Excel,PDF
November 30, 2011, 12:20 PM
njsden
subbu, you cannot have "intra" borders in a SUBHEAD or SUBFOOT. Only surrounding borders are possible with the current style sheet functionality.
If you need to have a border between line 1 and line 2 you may need to fake it using 2 SUBFOOT's.
DEFINE FILE CAR
DUMMY1/A10 = COUNTRY;
END
TABLE FILE CAR
SUM DEALER_COST NOPRINT RETAIL_COST NOPRINT CNT.CAR NOPRINT
COMPUTE CNTR/I8 = C2/C3; NOPRINT
BY DUMMY1 NOPRINT
BY COUNTRY
SUM DEALER_COST RETAIL_COST
BY DUMMY1 NOPRINT
BY COUNTRY
BY CAR
ON DUMMY1 SUBFOOT
"<+0> <+0> <+0><DEALER_COST<+0><RETAIL_COST"
ON COUNTRY SUBFOOT
"<+0> <+0> <+0> <+0><CNTR"
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT,
HEADALIGN=BODY,
BORDER=LIGHT,
BACKCOLOR=GRAY,
$
TYPE=SUBFOOT, BY=COUNTRY,
HEADALIGN=BODY,BORDER=LIGHT,BORDER-TOP-COLOR=BLACK,BORDER-BOTTOM-COLOR=BLACK,
LINE=1,ITEM=4,COLOR=RED,
$
ENDSTYLE
END