Mover columna en Diseñador de Informes Financieros

November 19, 2009, 09:43 AM

Hola que tal

Tengo un reporte, lo realice con el diseñador de informes financieros para poder dar un orden a los renglones segun yo quiero

todo funciona muy bien

mi duda es: ¿se puede cambiar de posicion la columna que contiene el titulo de los campos en los que me base para hacer el ordenamiento?

Saludos.

November 19, 2009, 09:54 AM

Francis Mariani

Si muestran un ejemplo de lo que tienes y lo que usted necesita

November 19, 2009, 11:35 AM

Pronuer

Amplio la informacion

tengo este codigo incial

  TABLE FILE MOVIES
 PRINT
 LISTPR
 WHOLESALEPR
 BY TITLE
 WHERE RECORDLIMIT EQ 20
 END

y me da un resultado mas o menos asi

title listpr wholesalepr
alien 19.98 14.55
all that jazz 19.98 13.99
altered states 19.98 14.99
...

cuando lo modifico con el diseñador de informes para que acomode las peliculas en el orden que yo quiero queda un codigo asi

 
TABLE FILE MOVIES
SUM
     'MOVIES.MOVINFO.LISTPR'
     'MOVIES.MOVINFO.WHOLESALEPR'
FOR
     'MOVIES.MOVINFO.TITLE'
'ROBOCOP' AS 'ROBOCOP' LABEL R1 OVER
'JAWS' AS 'JAWS' LABEL R2 OVER
RECAP R3=R1 + R2;
 AS 'Total parcial'
WHERE RECORDLIMIT EQ 20
ON TABLE NOTOTAL
END

y me da un resoltado mas o menos asi

listpr wholesalepr
ROBOCOP 19.98 11.50
JAWS 19.95 10.99
Total parcial 39.93 22.49

Mi Deseo es hacer esto

listpr wholesalepr Titulos
19.98 11.50 ROBOCOP
19.95 19.95 JAWS
39.93 39.93 Total parcial

Lo he intentando con el NOPRINT delante del for pero no muestra el "Total Parcial"

Muchas gracias

November 19, 2009, 11:45 AM

Francis Mariani

Use the SEQUENCE Style Sheet feature (Creating Reports With WebFOCUS Language > Laying Out the Report Page > Arranging Columns on a Page)

TABLE FILE MOVIES
SUM
     'MOVIES.MOVINFO.LISTPR'
     'MOVIES.MOVINFO.WHOLESALEPR'
FOR
     'MOVIES.MOVINFO.TITLE'
'ROBOCOP' AS 'ROBOCOP' LABEL R1 OVER
'JAWS' AS 'JAWS' LABEL R2 OVER
RECAP R3=R1 + R2;
 AS 'TOTAL PARCIAL'
WHERE RECORDLIMIT EQ 20
ON TABLE NOTOTAL
ON TABLE SET STYLE *
TYPE=REPORT, COLUMN=B1, SEQUENCE=99, COLOR=RED, $
ENDSTYLE
END

La característica de SEQUENCE puede causar otros problemas, pero lo intenta, puede trabajar para usted.

November 19, 2009, 11:58 AM

Pronuer

Gracias eso funciona bien

solo me quedo una duda mas como colocarle un titulo a esa columna he intentado poner esto

 FOR
     'MOVIES.MOVINFO.TITLE' AS 'TTITULOS'

pero me marca error sabras alguna sugerencia gracias

November 19, 2009, 12:31 PM

Francis Mariani

Desafortunadamente, usted no puede tener un título de la columna de la columna FOR.

Unfortunately, you can not have a column title for the FOR column.

November 19, 2009, 02:26 PM

Francis Mariani

FOR HTML ONLY

Here's how to use JavaScript to add text to the output of an HTML report. Since the FOR phrase does not allow for a column title, this method adds it using JavaScript. The JS function looks for all the TD elements that contain the column title just before the blank column title (in my example "WHOLESALEPR") and replaces the blank column-title with text (in my example "MOVIE").

SET LINES=6
SET PAGE=NOLEAD

TABLE FILE MOVIES
SUM
     'MOVIES.MOVINFO.LISTPR'
     'MOVIES.MOVINFO.WHOLESALEPR'
FOR
     'MOVIES.MOVINFO.TITLE'
'CITIZEN KANE'      LABEL R1 OVER
'MY LIFE AS A DOG'  LABEL R2 OVER
'DOG DAY AFTERNOON' LABEL R3 OVER
'VERTIGO'           LABEL R4 OVER
'DEATH IN VENICE'   LABEL R5 OVER
'ANNIE HALL'        LABEL R6 OVER
'CYRANO DE BERGERAC' LABEL R7 OVER
'DAS BOOT'          LABEL R8 OVER
'CASABLANCA'        LABEL R9 OVER

RECAP RTOT=R1 + R2 + R3 + R4 + R5 + R6 + R7 + R8 + R9;
 AS 'TOTAL PARCIAL'

ON TABLE NOTOTAL
ON TABLE SET STYLE *
TYPE=REPORT, COLUMN=B1, SEQUENCE=99, COLOR=RED, $
ENDSTYLE

ON TABLE HOLD AS H001 FORMAT HTMTABLE
END
-RUN

-HTMLFORM BEGIN
<html>
<head>
<script type="text/javascript">
function fixColTitle()
{
td = document.getElementsByTagName('TD');

for(i=0;i<td.length; i++)
  {
  if (td[i].innerHTML.indexOf('WHOLESALEPR') >= 0)
    {
    td[i+1].innerHTML = 'MOVIE';
    }
  }
}
</script>
</head>
<body onload="fixColTitle();">
!IBI.FIL.H001;
</body>
</html>
-HTMLFORM END