Hi,

I have multiple SUBTOTAL breaks where I want to have some displayed all time and some only when multilines occurs.
I thought that having something like that will works:

TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY
BY CAR
BY MODEL
BY SEATS
ON COUNTRY SUBTOTAL MULTILINES
ON CAR     SUBTOTAL
ON MODEL   SUBTOTAL MULTILINES
END

The problem is that using MULTILINES it's applied to all sort break as specified in doc.

quote:

MULTILINES
Suppresses the printing of a subtotal line for every sort break that has only one detail line, since the subtotal value is equal to this one value. Note that MULTI-LINES is a synonym for MULTILINES. MULTILINES is not supported with horizontal (ACROSS) sort fields.

SUMMARIZE
Recomputes values at every sort break.

RECOMPUTE
Recalculates values only at the specified sort break.

I'm wondering if it is possible to have MULTILINES react the same way as RECOMPUTE does : at specified sort break only ?
So I will always have SUBTOTAL for CAR, but only on MULTILINES for COUNTRY and MODEL.

All this without having to create the subtotals myself in a previous step and merging them to the detailed data where detail's row id will be 1 and subtotal will be 2 for then adding a sort on the row id after the BY SEATS (and the SUBTOTAL lines removed).

Is there another key word that I may not know yet ?

This message has been edited. Last edited by: MartinY,

You can use WHEN in subtotal, try below one.

SET LINES = 9999
DEFINE FILE CAR
MODEL_NEW/A50 = IF MODEL EQ '2002 2 DOOR AUTO' THEN '2002 2 DOOR' ELSE MODEL;
END
TABLE FILE CAR
SUM
COMPUTE CNTRY_CNT/I2=CNT.MODEL_NEW; NOPRINT
BY COUNTRY 
SUM 
COMPUTE MODEL_CNT/I2=CNT.SEATS; NOPRINT
BY COUNTRY 
BY CAR 
BY MODEL_NEW
SUM 
DEALER_COST
BY COUNTRY 
BY CAR 
BY MODEL_NEW
BY SEATS
ON COUNTRY SUBTOTAL
WHEN CNTRY_CNT GT 1;
ON CAR     SUBTOTAL
ON MODEL_NEW   SUBTOTAL 
WHEN MODEL_CNT GT 1;
ON TABLE SET STYLE *
TYPE=TITLE, BACKCOLOR=GREY, $
TYPE=SUBTOTAL, BY=COUNTRY, BACKCOLOR=BLUE, $
TYPE=SUBTOTAL, BY=CAR, BACKCOLOR=YELLOW, $
TYPE=SUBTOTAL, BY=MODEL, BACKCOLOR=RED, $
TYPE=GRANDTOTAL, BACKCOLOR=GREEN, $
ENDSTYLE
END

Thanks,
Ram

There is no keyword to achieve what you want, and Ram has one solution. I tend to use:

TABLE FILE CAR
SUM  DEALER_COST 
COMPUTE L_COUNTRY/A10 = LAST COUNTRY; NOPRINT
COMPUTE L_MODEL/A24 = LAST MODEL; NOPRINT
BY COUNTRY 
BY CAR 
BY MODEL 
BY SEATS 
ON COUNTRY SUBTOTAL WHEN COUNTRY EQ L_COUNTRY;
ON CAR SUBTOTAL 
ON MODEL SUBTOTAL WHEN MODEL EQ L_MODEL;
END

Thanks for your solution, I'll try them.

Will be great if that keyword may exist...