Is it possible to suppress (ie, collapse) blank detail records and only display the subheaders? I have a report that displays summary information for companies and if there are any comments for that company (ie, the detail records) then I need to show those (there could be several comments by date for each company...hence, these are the detail recs). I actually have this working fine, but for the cases where there are no comments, I'm getting a blank line which I'd like to collapse so that each successive subhead line shows right above the next one.

This message has been edited. Last edited by: Kerry,

If you are going to html then you can use CSS to deliver the sort of thing you want

in your .css stylesheet have something like

.NS {display:none}

and use it like this

 
TABLE FILE CAR
PRINT 
 SALES
COMPUTE HIDE/A1=IF SALES EQ 0 THEN 'Y' ELSE 'N'; NOPRINT
BY COUNTRY NOPRINT
ON COUNTRY SUBHEAD
"<COUNTRY"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT, CSSURL=http://localhost:9090/approot/ibisamp/s1.css,$
 TYPE=DATA, CLASS=NS, WHEN=HIDE EQ 'Y', $ 
ENDSTYLE
END
 

hmmm, i'll give that a shot. i wouldn't think it work b/c the data is returned in TD elements, and I'm not sure how display:none will work on TD. I'll update witht the results...

Mark,

It's down to using CSS. JG is assigning a CSS class to the TDs and that is what will control the display attribute.

T

A working example of what JG describes:

TABLE FILE CAR
PRINT 
 SALES
COMPUTE HIDE/A1=IF SALES EQ 0 THEN 'Y' ELSE 'N'; NOPRINT
BY COUNTRY NOPRINT
ON COUNTRY SUBHEAD
"<COUNTRY"
ON TABLE HOLD AS H001 FORMAT HTMTABLE
ON TABLE SET STYLE *
TYPE=DATA, CLASS=NS, WHEN=HIDE EQ 'Y', $ 
ENDSTYLE
END
-RUN

-HTMLFORM BEGIN
<style>
.NS { display:none; }
</style>
!IBI.FIL.H001.HTM;
-HTMLFORM END

Yep, works beautifully. Now, can something similar be done in PDF, since CSS won't apply?

For PDF you could change the font size to 1 and colour to white:

TABLE FILE CAR
PRINT 
 SALES
COMPUTE HIDE/A1=IF SALES EQ 0 THEN 'Y' ELSE 'N'; NOPRINT
BY COUNTRY NOPRINT
ON COUNTRY SUBHEAD
"<COUNTRY"
ON TABLE PCHOLD AS H001 FORMAT PDF
ON TABLE SET STYLE *
TYPE=DATA, SIZE=1, COLOR=WHITE, WHEN=HIDE EQ 'Y', $ 
ENDSTYLE
END
-RUN

Yep, works well. Thanks all.