[SOLVED] How to identify the first column of GRANDTOTAL

April 24, 2013, 04:00 PM

JC Zhu

I need to create a drill down link from the first column in the column total row. See following example. I can only seem to identify the entire row as "TYPE=GRANDTOTAL". So now the drill down link is set for all columns of the table while I only want the first column in the grand total row to have the link. Can that be done? I tried "COLUMN=N1" and it doesn't work.

TABLE FILE CAR
SUM
SALES
BY LOWEST COUNTRY
ACROSS LOWEST SEATS
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
$
TYPE=REPORT,
GRAPHCOLOR='GREEN',
$
TYPE=ACROSSVALUE,
ACROSS=1,
BACKCOLOR='WHITE',
$
TYPE=GRANDTOTAL,
URL=http://test,
$
TYPE=REPORT,
OBJECT=MENU,
COLOR='WHITE',
HOVER-COLOR=RGB(66 70 73),
BACKCOLOR=RGB(102 102 102),
HOVER-BACKCOLOR=RGB(218 225 232),
BORDER-COLOR='WHITE',
$
TYPE=REPORT,
OBJECT=STATUS-AREA,
COLOR='WHITE',
BACKCOLOR=RGB(102 102 102),
$
TYPE=REPORT,
OBJECT=CURRENT-ROW,
HOVER-BACKCOLOR=RGB(218 225 232),
BACKCOLOR=RGB(200 200 200),
$
TYPE=REPORT,
OBJECT=CALC-AREA,
COLOR='WHITE',
BACKCOLOR=RGB(102 102 102),
$
ENDSTYLE
END

This message has been edited. Last edited by: <Kathryn Henning>,

April 24, 2013, 04:07 PM

Severus.snape

Hi,

Try
TYPE=GRANDTOTAL,
COLUMN=ROWTOTAL(1),
URL=http://test,
$

replace 1 with what ever column number you want.

thanks
Sashanka

April 24, 2013, 04:23 PM

Severus.snape

Never mind the above code ..it does not work..
but I tested out this one and it works:

 
TABLE FILE CAR
SUM 
SALES
BY LOWEST COUNTRY
ACROSS LOWEST SEATS
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
-*INCLUDE = endeflt,
$
TYPE=REPORT,
GRAPHCOLOR='GREEN',
$
TYPE=ACROSSVALUE,
ACROSS=1,
BACKCOLOR='WHITE',
$
TYPE=GRANDTOTAL,
COLUMN=C2,
URL=http://test,
$
TYPE=REPORT,
OBJECT=MENU,
COLOR='WHITE',
HOVER-COLOR=RGB(66 70 73),
BACKCOLOR=RGB(102 102 102),
HOVER-BACKCOLOR=RGB(218 225 232),
BORDER-COLOR='WHITE',
$
TYPE=REPORT,
OBJECT=STATUS-AREA,
COLOR='WHITE',
BACKCOLOR=RGB(102 102 102),
$
TYPE=REPORT,
OBJECT=CURRENT-ROW,
HOVER-BACKCOLOR=RGB(218 225 232),
BACKCOLOR=RGB(200 200 200),
$
TYPE=REPORT,
OBJECT=CALC-AREA,
COLOR='WHITE',
BACKCOLOR=RGB(102 102 102),
$
ENDSTYLE
END

April 24, 2013, 04:33 PM

JC Zhu

Thanks for the quick answer. Is there a way to have the link from the "Total" cell in the last row? That's what I meant by first column in my original post.

April 25, 2013, 07:07 AM

Alex

TYPE=GRANDTOTAL, COLUMN=C2, FOCEXEC=ibisamp/carinst,$

April 25, 2013, 08:33 AM

Tom Flynn

  
SET ASNAMES = ON, NODATA = 0
TABLE FILE CAR
SUM 
   SALES
  BY COUNTRY
  BY SEATS
 ON TABLE HOLD AS HOLD1
END
-RUN
DEFINE FILE HOLD1
  XCOUNTRY/A10 = 'Total';
END
TABLE FILE HOLD1
SUM 
   SALES
  BY XCOUNTRY AS 'COUNTRY'
  BY SEATS
 ON TABLE HOLD AS HOLD2
END
-RUN
TABLE FILE HOLD1
PRINT 
   SALES
  BY COUNTRY
  BY SEATS
 ON TABLE HOLD AS HOLD3
MORE 
FILE HOLD2
END
-RUN
DEFINE FILE HOLD3
 XSORT/I2 = DECODE COUNTRY('Total' 99 ELSE 1);
END   
TABLE FILE HOLD3
SUM 
SALES
BY XSORT NOPRINT
BY COUNTRY
ACROSS SEATS
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
$
TYPE=REPORT,GRAPHCOLOR='GREEN',$
TYPE=ACROSSVALUE,ACROSS=1,BACKCOLOR='WHITE',$
TYPE=DATA, COLUMN=N2, FOCEXEC=PROGRAM_NAME, STYLE=BOLD, COLOR=BLUE, WHEN=COUNTRY EQ 'Total',$
ENDSTYLE
END
-EXIT

April 25, 2013, 10:36 AM

JC Zhu

Tom, thanks for the solution. It works. I was hoping there is a way to identify that total column by using "type=GRANDTOTAL", but it looks like WebFocus does not really support that.

May 07, 2013, 01:36 PM

Severus.snape

This feature --identifying the TOTAL tags in the style sheet is available now on the RS version 7.7.05..along with some other cool things.

thanks
Sashanka

April 02, 2014, 01:28 PM

Francis Mariani

quote:
identifying the TOTAL tags in the style sheet is available now on the RS version 7.7.05..along with some other cool things

I wonder where this is documented, can't seem to find anything...

April 02, 2014, 01:58 PM

Francis Mariani

It appears to be documented ONLY in the New Features doc:

WebFOCUS New Features Version 7 Release 7.05 > Reporting Language Enhancements > Styling Tags for SUBTOTAL and GRANDTOTAL Lines

How to Style Subtotal and Grand Total Tags

TYPE={SUBTOTAL|GRANDTOTAL}, OBJECT=TAG,
  [FONT=font], [SIZE=size], [STYLE=style],
  [COLOR={color|RGB({r g b|#hexcolor})],
  [drilltype=drillparms], $

OBJECT=TAG is the key.

April 02, 2014, 02:08 PM

Francis Mariani

TABLE FILE CAR
SUM
LENGTH
BY COUNTRY
ACROSS BODYTYPE AS ''
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'

ON TABLE SET PAGE NOLEAD
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='ARIAL', SIZE=9, BORDER=1, BORDER-COLOR=SILVER, $

TYPE=TITLE, COLOR=BLUE, STYLE=BOLD, $
TYPE=ACROSSVALUE, COLOR=BLUE, STYLE=BOLD, $
TYPE=GRANDTOTAL, STYLE=BOLD, $

TYPE=GRANDTOTAL, OBJECT=TAG, COLOR=GREEN, FOCEXEC=NONE, $

TYPE=GRANDTOTAL, 
FOCEXEC=APP/CHG_MGMT_AGING_DETAIL(BODYTYPE=A1), $

ENDSTYLE
END