All,

I have been trying to work this out for a while now, and has something that works... but I think its really the wrong way to do it.

Also, all drill down functionality comes over the excel, I've tried to skip over that section without being able to.

Anyone have any ideas?

-DEFAULT &FORMAT = HTML


TABLE FILE E3ITEMA
SUM
     E3ITEMA.E3ITEMA.ItemValue/D6 AS 'Total Count of Items'
     E3ITEMA.E3REVS.DueNUM/P6 AS 'Due Count'
     E3ITEMA.E3REVS.PlaceNUM/P6 AS 'Placed Count,'
BY  LOWEST E3ITEMA.E3BUYR.BNAME AS 'Buyer Name'
ON TABLE SUBHEAD
"Buyer SoQ Actual > 90 Days"
ON TABLE SUBFOOT
"Export To Excel"
WHERE ( E3ITEMA.E3ITEMA.SoQDays GT 90 );
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET BYDISPLAY ON
ON TABLE SET FORMULTIPLE ON
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT &FORMAT
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=REPORT,
     GRAPHCOLOR='GREEN',
$
TYPE=DATA,
     COLUMN=N3,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N4,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N1,
     TARGET='_self',
     JUSTIFY=LEFT,
     FOCEXEC=app/high_soq_item( \
     BNAME=N1 \
     ),
$
TYPE=DATA,
     COLUMN=N2,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N3,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N4,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N1,
     TARGET='_self',
     FOCEXEC=app/high_soq_item( \
     BNAME=N1 \
     ),
$
TYPE=TITLE,
     COLUMN=N2,
     JUSTIFY=CENTER,
$
TYPE=TABFOOTING,
     LINE=1,
     JUSTIFY=LEFT,
$
TYPE=TABFOOTING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=8,
     STYLE=ITALIC,
     TARGET='_blank',
     FOCEXEC=app/high_soq( \
     FORMAT='EXL07' \
     ),
$
TYPE=GRANDTOTAL,
     JUSTIFY=CENTER,
$
TYPE=REPORT,
     OBJECT=MENU,
     COLOR='WHITE',
     HOVER-COLOR=RGB(66 70 73),
     BACKCOLOR=RGB(102 102 102),
     HOVER-BACKCOLOR=RGB(218 225 232),
     BORDER-COLOR='WHITE',
$
TYPE=REPORT,
     OBJECT=STATUS-AREA,
     COLOR='WHITE',
     BACKCOLOR=RGB(102 102 102),
$
TYPE=REPORT,
     OBJECT=CURRENT-ROW,
     HOVER-BACKCOLOR=RGB(218 225 232),
     BACKCOLOR=RGB(200 200 200),
$
TYPE=REPORT,
     OBJECT=CALC-AREA,
     COLOR='WHITE',
     BACKCOLOR=RGB(102 102 102),
$
ENDSTYLE
END

This message has been edited. Last edited by: John C.,

Why can't you do something like this - separate the drilldowns from the other styling and use a GOTO:

-DEFAULT &FORMAT = HTML


TABLE FILE E3ITEMA
SUM
     E3ITEMA.E3ITEMA.ItemValue/D6 AS 'Total Count of Items'
     E3ITEMA.E3REVS.DueNUM/P6 AS 'Due Count'
     E3ITEMA.E3REVS.PlaceNUM/P6 AS 'Placed Count,'
BY  LOWEST E3ITEMA.E3BUYR.BNAME AS 'Buyer Name'
ON TABLE SUBHEAD
"Buyer SoQ Actual > 90 Days"
ON TABLE SUBFOOT
"Export To Excel"
WHERE ( E3ITEMA.E3ITEMA.SoQDays GT 90 );
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET BYDISPLAY ON
ON TABLE SET FORMULTIPLE ON
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT &FORMAT
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=REPORT,
     GRAPHCOLOR='GREEN',
$
TYPE=DATA,
     COLUMN=N3,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N4,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N2,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N3,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N4,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     COLUMN=N2,
     JUSTIFY=CENTER,
$
TYPE=TABFOOTING,
     LINE=1,
     JUSTIFY=LEFT,
$
TYPE=GRANDTOTAL,
     JUSTIFY=CENTER,
$
TYPE=REPORT,
     OBJECT=MENU,
     COLOR='WHITE',
     HOVER-COLOR=RGB(66 70 73),
     BACKCOLOR=RGB(102 102 102),
     HOVER-BACKCOLOR=RGB(218 225 232),
     BORDER-COLOR='WHITE',
$
TYPE=REPORT,
     OBJECT=STATUS-AREA,
     COLOR='WHITE',
     BACKCOLOR=RGB(102 102 102),
$
TYPE=REPORT,
     OBJECT=CURRENT-ROW,
     HOVER-BACKCOLOR=RGB(218 225 232),
     BACKCOLOR=RGB(200 200 200),
$
TYPE=REPORT,
     OBJECT=CALC-AREA,
     COLOR='WHITE',
     BACKCOLOR=RGB(102 102 102),
$

TYPE=TABFOOTING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=8,
     STYLE=ITALIC,
$

-IF &FORMAT EQ 'EXL2K' OR 'EXL07' GOTO NO_DRILLDOWN;

TYPE=TITLE,
     COLUMN=N1,
     TARGET='_self',
     FOCEXEC=app/high_soq_item( \
     BNAME=N1 \
     ),
$
TYPE=DATA,
     COLUMN=N1,
     TARGET='_self',
     JUSTIFY=LEFT,
     FOCEXEC=app/high_soq_item( \
     BNAME=N1 \
     ),
$
TYPE=TABFOOTING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     TARGET='_blank',
     FOCEXEC=app/high_soq( \
     FORMAT='EXL07' \
     ),
$
-NO_DRILLDOWN

ENDSTYLE
END

If you're developing in the GUI then this won't work, but this *might*:

COMPUTE a new column:

COMPUTE DRILL_FLAG/A1 = IF '&FORMAT' IN ('EXL2K', 'EXL07') THEN 'N' ELSE 'Y'; NOPRINT

Use it in WHEN clauses:

TYPE=TITLE,
COLUMN=N1,
TARGET='_self',
FOCEXEC=app/high_soq_item( \
BNAME=N1 \
),
WHEN= DRILL_FLAG EQ 'Y',
$

Francis,

The Drill_flag with the GUI didn't seem to work, however the no_drilldown method works great.

Thank you so much!

This message has been edited. Last edited by: John C.,

Glad it worked out.

By the way: "I" is for HIM, "E" is for HER!

Ack sorry!