I am still learning WebFOCUS and I have a set of requirements that I have been handed that I am not even sure is possible to complete.
http://s855.photobucket.com/al...w¤t=report.jpg (link in case image does not show up in post)

Based on the image, can someone let me know if the following are possible:
1) Dropdown selector in a title column.
2) Graph in a table cell
3) Pagination (using javascript?)

Also, if you could give me an idea on the level of effort it would take so I can let the person who created the requirements if it is worth pursuing.

Thanks!

This message has been edited. Last edited by: Kerry,

Cody,

I believe you can do all of that in webfocus however, it's not your simple webfocus report.

1. Dropdown in the title would be a mixture of webfocus, html code, javascript code.
2. Would be links to prepared sparkline images.
3. Webfocus has methods for pagination.

I would guess a day or two effort, if all the data is prepared and known.

My two cents,
--wg

Cody,
It looks like a normal HTML page with images and a mouse-over drop down.

Its very much possible in WebFOCUS.
Here is the solutions that I will prefer.
1. Create

<DIV>

elements and using onmouseover event change visible property of the elements.
2. Save graph output as images. Use -HTMLFORM and build report output. Create a define column like this

IMG_COLUMN/A200='<IMG SRC='''| graph_output_1.jpg | '>';

Call in the TABLE FILE request.
3. To create pagination with row limit. Use a counter in the final output and limit the display using WHERE CNTR GT 11 AND CNTR LE 20. You can dynamically change the filter values based on user selected page number and row count. Use dialogue manager variables(-SET &START_ROW=11;, -SET &END_ROW=20 for that.

Finally to do all these, go for HTMLFORM. That will make things easier.

The beginning of a solution:

  
-* File cody01.fex
-*
-* The dropdown in title
-SET &STITLE='<Select name="Cody"><option value="1">Total Sales per Car</option><option value="2">Other Option</option></Select>';
-*
-* Limit number of lines/page
SET LINES = 12
-*
-* Change 0 to something visible
DEFINE FILE CAR
SALES/I6=IF SALES EQ 0 THEN 2000 ELSE SALES;
END
-*
-* Report
TABLE FILE CAR
SUM 
     SALES AS '&STITLE'
BY CAR
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
-*
-* Use WF WebViewer for paging
ON TABLE SET WEBVIEWER ON
ON TABLE SET WEBVIEWTARG OFF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
     GRAPHTYPE=DATA,
     COLUMN=N2,
     GRAPHLENGTH=1.000000,
     GRAPHWIDTH=0.1,
     GRAPHCOLOR='TEAL',
$
TYPE=REPORT,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=LIGHT,
     BORDER-LEFT=LIGHT,
     BORDER-RIGHT=LIGHT,
     BORDER-TOP-COLOR=RGB(153 153 153),
     BORDER-BOTTOM-COLOR=RGB(153 153 153),
     BORDER-LEFT-COLOR=RGB(153 153 153),
     BORDER-RIGHT-COLOR=RGB(153 153 153),
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N2,
     FONT='ARIAL',
     SIZE=14,
     COLOR='GRAY',
     STYLE=NORMAL,
$
TYPE=DATA,
     COLUMN=N1,
     FONT='ARIAL',
     SIZE=14,
     COLOR='GRAY',
     STYLE=NORMAL,
$
TYPE=TITLE,
     COLUMN=N2,
     SIZE=14,
     COLOR='GRAY',
     STYLE=NORMAL,
     JUSTIFY=RIGHT,
$
TYPE=TITLE,
     COLUMN=N1,
     FONT='ARIAL',
     SIZE=14,
     COLOR='GRAY',
     STYLE=NORMAL,
$
ENDSTYLE
END

Thanks for the help. I certainly have a much better place to start from now than I did.