In this simple example, why does &prevmonth show as '1' instead of '01'?

-SET &CURYR = &DATEYY;
-SET &PREVYR = &DATEYY - 1;
-SET &CURMO = &DATEM ;
-SET &PREVMONTH = &CURMO - 1;
-SET &PREVMO = IF &CURMO  EQ 1 THEN 12 ELSE &PREVMONTH.EVAL;
-SET &CURRYM = '&DATEYY.EVAL' | '&DATEM.EVAL';
-SET &PREVYM = '&PREVYR.EVAL' | '&PREVMO.EVAL';
-SET &MODM = EDIT (MODIFY_DATE,'$$$$$99$$$');
-TYPE &CURYR &CURMO &PREVMO &CURRYM &PREVYM &CURMO &PREVMONTH
-RUN
-EXIT  

This message has been edited. Last edited by: Donald,

Because you're working with integers, not dates.

-SET &ECHO=ALL;

-SET &CURYR = &DATEYY;
-SET &PREVYR = &DATEYY - 1;
-SET &CURMO = &DATEM ;
-SET &PREVMONTH = &CURMO - 1;
-SET &PREVMONTH = IF &PREVMONTH LT 10 THEN '0' | &PREVMONTH ELSE &PREVMONTH;
-SET &PREVMO = IF &CURMO  EQ 1 THEN 12 ELSE &PREVMONTH;
-SET &CURRYM = &DATEYY | &DATEM.;
-SET &PREVYM = &PREVYR | &PREVMO;
-SET &MODM = EDIT (MODIFY_DATE,'$$$$$99$$$');

-TYPE CURYR    : &CURYR
-TYPE CURMO    : &CURMO
-TYPE PREVMO   : &PREVMO
-TYPE CURRYM   : &CURRYM
-TYPE PREVYM   : &PREVYM
-TYPE CURMO    : &CURMO
-TYPE PREVMONTH: &PREVMONTH

Tom beat me to the punch.

You don't need the EVAL suffix here.

Because you are treating it as a numeric value and not as ac actual DATE component.

02 - 1 => 1

If you need to go to the previous month and have it always represented as "MM" you should use DATE functions instead; if we were still in January, PREVMONTH should be "12" but your expression would return => 01 - 1 -> 0 which is wrong.

Try something like:

-SET &PREVMONTH = EDIT(DATECVT(DATEADD(DATECVT(&YYMD, 'I8YYMD', 'YYMD'), 'M', -1), 'YYMD', 'A8YYMD'), '$$$$99$$');

Not necessarily short but surely safer!

- Neftali.

Francis,

We both had essentially the same thing, so, I deleted mine!

Better yet, just determine what your previous month is and from there obtain all of the independent components you need:

quote:

-SET &PREVMONTH = DATECVT(DATEADD(DATECVT(&YYMD, 'I8YYMD', 'YYMD'), 'M', -1), 'YYMD', 'A8YYMD');
-SET &PREVMO = EDIT(&PREVMONTH, '$$$$99$$');
-SET &PREVYM = EDIT(&PREVMONTH, '999999$$');
...

Got it, Thank You

You can also use the legacy function AYM to add/subtract months.

-SET &PREVYY  = &DATEYY - 1 ;
-SET &CURYYM  = &DATEYY | &DATEM ;
-SET &PREVYYM = AYM(&CURYYM,-1,'I6');
-*
-TYPE DATEYY  = &DATEYY
-TYPE PREVYY  = &PREVYY
-TYPE CURYYM  = &CURYYM
-TYPE PREVYYM = &PREVYYM