HELP! I am trying to format (control squeeze, and color) columns (not the rows) created with OVER and ACROSS. But I don't know what TYPE=' ' should be. I tried TYPE=REPORT, COLUMN=N2 and TYPE=ACROSSVALUE etc. but nothing. My fex is the following.

SUM
LINE AS 'LOI Counts by Current Status' OVER
CLOSEDEALS AS 'Closed LOIs' OVER
LOINUMBER AS '#Active LOIs' OVER
BACKBURNERDEALS AS 'Backburner LOIs' OVER
DEADEALS AS 'Dead LOIs' OVER
ALL_LOIS AS 'Total LOIs' OVER
LINE AS 'Disposition Percentages by #LOIs' OVER
COMPUTE CLOSED_PERCENT/D20.1%=CLOSEDEALS / ALL_LOIS * 100; AS '% Closed Deals' OVER
COMPUTE DEAD_PERCENT/D20.1%=DEADEALS / ALL_LOIS * 100; AS '% Dead Deals' OVER
COMPUTE BACK_PERCENT/D20.1%=BACKBURNERDEALS / ALL_LOIS * 100; AS '% Backburner Deals' OVER
COMPUTE ACTIVE_PERCENT/D20.1%=ACTIVEDEALS / ALL_LOIS * 100; AS '% Active Deals' OVER
LINE AS 'Cumulative Rent Amounts by Status' OVER
CLOIRENT AS 'Closed Rent' OVER
DLOIRENT AS 'Dead Rent' OVER
BLOIRENT AS 'Backburner Rent' OVER
ALOIRENT AS 'Active LOI Rent' OVER
LINE AS 'Avg. Monthly Rent by Status' OVER
COMPUTE AVGCLOIRENT/D20M = CLOIRENT / CLOSEDEALS ; AS 'Avg. Closed LOI Rent' OVER
COMPUTE AVGDLOIRENT/D20M = DLOIRENT / DEADEALS ; AS 'Avg. Dead LOI Rent' OVER
COMPUTE AVGBLOIRENT/D20M = BLOIRENT / BACKBURNERDEALS ; AS 'Avg. Backburner LOI Rent' OVER
COMPUTE AVGLOIRENT/D20M = ALOIRENT / ACTIVEDEALS ; AS 'Avg. Active LOI Rent' OVER
LINE AS 'Avg. IRR by Status' OVER
COMPUTE CLOSEDLOIIRR/D20.1% = CLOIIRRAMOUNT / CLOIRENT * 100; AS 'Closed IRR' OVER
COMPUTE DEADLOIIRR/D20.1% = DLOIIRRAMOUNT / DLOIRENT * 100; AS 'Dead IRR' OVER
COMPUTE BACKLOIIRR/D20.1% = BLOIIRRAMOUNT / BLOIRENT * 100; AS 'Backburner IRR' OVER
COMPUTE ACTIVELOIIRR/D20.1% = ALOIIRRAMOUNT / ALOIRENT * 100; AS 'Active IRR' OVER
LINE AS 'Avg. Purchase Price Multiple by Status' OVER
COMPUTE CLOSEDLOIMULT/D20.1 = CMULTIPLEAMOUNTIS / CLOIRENT; AS 'Closed Multiple ' OVER
COMPUTE DEADLOIMULT/D20.1 = DMULTIPLEAMOUNTIS / DLOIRENT; AS 'Dead Multiple' OVER
COMPUTE BACKLOIMULT/D20.1 = BMULTIPLEAMOUNTIS / BLOIRENT; AS 'Backburner Multiple ' OVER
COMPUTE ACTIVELOIMULT/D20.1 = AMULTIPLEAMOUNTIS / ALOIRENT; AS 'Active Multiple' OVER
-*COMPUTE AVGMONTHSTOLOI/D12.2=ACTIVETIME / ACTIVEDEALS ; AS 'Avg. Months to LOI'
CLOSEDOVER2500 NOPRINT OVER
LINE AS 'Duration Analysis by Status' OVER
COMPUTE AVGMONTHSTOCLOSED/D12.1=CLOSEDTIME / CLOSEDEALS ; AS 'Avg. Months to Close' OVER
COMPUTE CLOSEDIN3MON/D12.1%=3MONCLOSED / ALL_LOIS * 100; AS '% Closed @ 3 Mo' OVER
COMPUTE CLOSEDIN6MON/D12.1%=6MONCLOSED / ALL_LOIS * 100; AS '% Closed @ 6 Mo' OVER
COMPUTE OVER2500/D12.1%=CLOSEDOVER2500 /ALL_LOIS * 100; AS '% Closed 2.5K+' OVER
COMPUTE AVGMONTHSTODEAD/D12.1=DEADTIME / DEADEALS ; AS 'Avg. Months to Dead' OVER
COMPUTE AVGMONTHSTOBACK/D12.1=BACKTIME / BACKBURNERDEALS ; AS 'Avg. Months to Backburner' OVER
CLOSEDOVER2500 NOPRINT
ACROSS HIGHEST LOIYEAR NOPRINT
ACROSS HIGHEST QTRYR IN 60 AS ''
HEADING
"UNISON SITE MANAGEMENT"
"Quarterly Trend Analysis for "Report run by: &IBIMR_user<+0> Report Run on: &DATEtrMDYYON TABLE SUBFOOT
" "
"Months comparisons are calcuated from LOI Signature Received by Legal date to Status Change Date"
WHERE LOIYEAR EQ 2006 OR 2005
ON TABLE SET NODATA '0'
ON TABLE NOTOTAL
ON TABLE SET EMPTYCELLS OFF
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT PDF CLOSE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
LEFTMARGIN=0.250000,
RIGHTMARGIN=0.250000,
BOTTOMMARGIN=0.0,
TOPMARGIN=.0,
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,
RIGHTGAP=.3,
LEFTGAP=.05,
$
TYPE=REPORT,
GRID=OFF,
FONT='TIMES NEW ROMAN',
SIZE=8,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
TYPE=HEADING,
SIZE=10,
COLOR='NAVY',
STYLE=BOLD+ITALIC,
FONT='ARIAL',
JUSTIFY=CENTER,
$
TYPE=HEADING,
LINE=4,
OBJECT=TEXT,
ITEM=1,
JUSTIFY=LEFT,
WIDTH=3.0,
SIZE=7,
$
TYPE=HEADING,
LINE=4,
OBJECT=TEXT,
ITEM=2,
JUSTIFY=RIGHT,
WIDTH=7.5,
SIZE=7,
$
TYPE=ACROSSVALUE,
ACROSS=1,
JUSTIFY=RIGHT,
$
TYPE=ACROSSVALUE,
ACROSS=2,
JUSTIFY=CENTER,
$
TYPE=REPORT,
ACROSSCOLUMN=N5,
SQUEEZE=.405556,
$
TYPE=TITLE,
COLUMN=N1,
BACKCOLOR='NAVY',
STYLE=BOLD,
COLOR='WHITE',
$
TYPE=TITLE,
COLUMN=N7,
BACKCOLOR='NAVY',
STYLE=BOLD,
COLOR='WHITE',
$
TYPE=TITLE,
COLUMN=N12,
BACKCOLOR='NAVY',
STYLE=BOLD,
COLOR='WHITE',
$
TYPE=TITLE,
COLUMN=N17,
BACKCOLOR='NAVY',
STYLE=BOLD,
COLOR='WHITE',
$
TYPE=TITLE,
COLUMN=N22,
BACKCOLOR='NAVY',
STYLE=BOLD,
COLOR='WHITE',
$
TYPE=TITLE,
COLUMN=N27,
BACKCOLOR='NAVY',
STYLE=BOLD,
COLOR='WHITE',
$
TYPE=TITLE,
COLUMN=N33,
BACKCOLOR='NAVY',
STYLE=BOLD,
COLOR='WHITE',
$
TYPE=REPORT,
IMAGE=app/unison.gif,
POSITION=(0.263889 0.305556),
SIZE=(1.875000 0.305556),
$
ENDSTYLE
END

Clay Williams
WebFOCUS 7.1.4

Clay,

I'm afraid that you're going to have to count the COLUMNs in your output and if they're variable in number then you might well have a problem.

Try this small piece of code as an example -

TABLE FILE GGSALES
 SUM DOLLARS AS 'Dollar Amount' OVER
     UNITS   AS ' No. of Units'
ACROSS REGION
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE-NUM NOPAGE
ON TABLE SET STYLE *
  TYPE=DATA, COLUMN=N1, BACKCOLOR=YELLOW, $
  TYPE=DATA, COLUMN=N2, BACKCOLOR=YELLOW, $
  TYPE=DATA, COLUMN=N5, BACKCOLOR=YELLOW, $
  TYPE=DATA, COLUMN=N6, BACKCOLOR=YELLOW, $
ENDSTYLE
END
-RUN

Note that I've only coloured "columns" 2 and 4 of the resultant report.

There may be an alternative solution, but I haven't come across it yet....

T

Tony,

Thanks for taking the time to help with you quick solution. What is weird that got me of track are the columns not being in sequential order so they skipping N3, N4 then N6, N7 it's strange but I'm into results Thanks again.

Clay,

One thing to remember is the even output fields tagged with NOPRINT have to be counted. To my reckoning you have 41 fields in each "column" of output.

Good luck

T

Tony, It's great, It would 've been tough without this find to figure out how to backcolor all values/data of a column in OVER with ACROSS.

Thanks !!

quote:

Originally posted by Tony A:
Clay,

I'm afraid that you're going to have to count the COLUMNs in your output and if they're variable in number then you might well have a problem.

Try this small piece of code as an example -

TABLE FILE GGSALES
 SUM DOLLARS AS 'Dollar Amount' OVER
     UNITS   AS ' No. of Units'
ACROSS REGION
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE-NUM NOPAGE
ON TABLE SET STYLE *
  TYPE=DATA, COLUMN=N1, BACKCOLOR=YELLOW, $
  TYPE=DATA, COLUMN=N2, BACKCOLOR=YELLOW, $
  TYPE=DATA, COLUMN=N5, BACKCOLOR=YELLOW, $
  TYPE=DATA, COLUMN=N6, BACKCOLOR=YELLOW, $
ENDSTYLE
END
-RUN

Note that I've only coloured "columns" 2 and 4 of the resultant report.

There may be an alternative solution, but I haven't come across it yet....

T