By way of background I have a requirement to do a ReportCaster BURST distribution of a group of reports.

We've used ReportCaster to BURST a single report, this is the first time we are needing to send a group of reports, to a particular email address.

My understanding is that we need to use a Coordinated Compound report to do this.

This is my first encounter with Coordinated Compound reports.

The following models my code:

SET PAGE-NUM=OFF

COMPOUND LAYOUT PCHOLD FORMAT DHTML

SECTION=S1, LAYOUT=ON, MERGE=ON, ORIENTATION=LANDSCAPE, $
 PAGELAYOUT=1, $
  COMPONENT=Sales, TYPE=REPORT, POSITION=(1 1), DIMENSION=(4 4), $
  COMPONENT=Units, TYPE=REPORT, POSITION=(1 4), DIMENSION=(4 4), $
END

SET COMPONENT=Sales
 TABLE FILE GGSALES
 "Sales report for <REGION"
 " "
 SUM DOLLARS/F8M
 BY REGION NOPRINT
 BY ST
 BY CITY
 ON TABLE HOLD FORMAT PDF
 ON TABLE SET STYLE *
  TYPE=REPORT, FONT=HELVETICA, COLOR=RED, SQUEEZE=ON, $
 END

SET COMPONENT=Units
 TABLE FILE GGSALES
 "Number of unit sales per product for <REGION"
 " "
 SUM CNT.UNITS AS 'Number of units sold'
 BY REGION NOPRINT
 BY PRODUCT
 ON TABLE HOLD FORMAT PDF
 ON TABLE SET STYLE *
  TYPE=REPORT, FONT=HELVETICA, COLOR=BLUE, SQUEEZE=ON, $
 END
COMPOUND END  

And renders like this:

My question is how to get the second report (Number of units) to position relative to the first report (Sales).

Currently I am setting the position yAxis to '4' for the second report, but in reality, I won't know how long the first report is, i.e., it could list three states one time and fifty the next.

Can I set the second report relative to the first?

(I guess I can do some pre-processing like: calculate the number rows in the first report, do some math to estimate the size, set a variable equal to the size estimate, then make the yAxis value a amper variable, in place of the '4'. And I am thinking there is a better way to set a relative position, that I am not seeing.)

This message has been edited. Last edited by: FP Mod Chuck,

Read a little further in the 'Creating Reports' manual and found 'RELATIVE*' parms.

So, I think I should be all set.

SET PAGE-NUM=ON

COMPOUND LAYOUT PCHOLD FORMAT DHTML

SECTION=S1, LAYOUT=ON, MERGE=ON, ORIENTATION=LANDSCAPE, $
 PAGELAYOUT=1, $
  COMPONENT=Sales, TYPE=REPORT, POSITION=(1 1), DIMENSION=(* *), $
  COMPONENT=Units, TYPE=REPORT, POSITION=(1 +.25), DIMENSION=(* *), RELATIVE-TO='Sales',
   RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT, $
END

SET COMPONENT=Sales
 TABLE FILE GGSALES
 "Sales report for <REGION"
 " "
 SUM DOLLARS/F8M
 BY REGION NOPRINT
 BY ST
 BY CITY
 ON TABLE HOLD FORMAT PDF
 ON TABLE SET STYLE *
  TYPE=REPORT, FONT=HELVETICA, COLOR=RED, SQUEEZE=ON, $
 END

SET COMPONENT=Units
 TABLE FILE GGSALES
 "Number of unit sales per product for <REGION"
 " "
 SUM CNT.UNITS AS 'Number of units sold'
 BY REGION NOPRINT
 BY PRODUCT
 ON TABLE HOLD FORMAT PDF
 ON TABLE SET STYLE *
  TYPE=REPORT, FONT=HELVETICA, COLOR=BLUE, SQUEEZE=ON, $
 END
COMPOUND END