Hi Guys,

Whilst im learning WebFOCUS i knocked up this little piece of code to help remind me what's what in terms of report elements like:

SUBHEAD
HEADING
TITLE
REPORT
SUBTOTAL
GRANDTOTAL
FOOTING
SUBFOOT

I did this because find myself forgetting and mixing up the element names when im coding these things so if you run the code below it should give you a little report you can use to remind yourself what all the elements are and where they come out on your report.

Its only really useful for newbies as advanced users or veterans will know all this from memory but i feel this will help me learn and remember this better so thought i'd share.

Vets feel free to jump in and correct any mistakes- i hope i haven't made any.

 DEFINE FILE CAR
TYPE_1/A10=IF TYPE EQ 'COUPE' THEN 'REPORT' ELSE 'NADA';
COUNTRY_1/A10=IF COUNTRY EQ 'ITALY' THEN 'ACROSS' ELSE 'NADA';
END

TABLE FILE CAR
SUM RCOST
BY TYPE_1 AS TITLE SUBTOTAL AS 'BY SUBTOTAL'
ACROSS COUNTRY_1  AS ACROSS-TITLE
WHERE TYPE EQ 'COUPE'
HEADING
"HEADING"
FOOTING BOTTOM
"FOOTING"
ON TABLE COLUMN-TOTAL AS GRANDTOTAL AND ROW-TOTAL  AS ROWTOTAL
ON TABLE SUBHEAD
"SUBHEAD"
ON TABLE SUBFOOT
"SUBFOOT"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET PAGE-NUM OFF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,PAGESIZE='A4',PAGECOLOR=WHITE,ORIENTATION=LANDSCAPE,HEADALIGN=INTERNAL,$

TYPE=SUBHEAD    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=GREEN ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=HEADING    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=GREY  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=TITLE      ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=RED   ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=ACROSSTITLE,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=PINK  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=ACROSS     ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=SILVER,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=REPORT     ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=WHITE ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBTOTAL   ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=YELLOW,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=GRANDTOTAL ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=ORANGE,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=FOOTING    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=GREY  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBFOOT    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=BLUE  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$

END
-EXIT
 

This message has been edited. Last edited by: nubi,

Nubi,

Since you are using ON TABLE SUBHEAD/ON TABLE SUBFOOT these are special SUBHEADs and SUBFOOTs identified by using the keywords TYPE=TABHEADING and TYPE=TABFOOTING.

If your example included ON TYPE_1 SUBHEAD or SUBFOOT then these are identified with the normal TYPE=SUBHEAD and TYPE=SUBFOOT keywords.

Hi Mickey,

ah this makes it complete- to be honest i was looking at my code and wondering why the subs weren't adpoting the colours i was specifying but realise now that a sub on a table gives you the TABHEADING and a sub on a field gives you a 'proper' subheading.

Ive amended the code in case anyone has run it because Mickeys suggestion has made it more comprehensive.

DEFINE FILE CAR
TYPE_1/A10=IF TYPE EQ 'COUPE' THEN 'REPORT' ELSE 'NADA';
COUNTRY_1/A10=IF COUNTRY EQ 'ITALY' THEN 'ACROSS' ELSE 'NADA';
END
 
TABLE FILE CAR
SUM RCOST
BY TYPE_1 AS TITLE SUBTOTAL AS 'BY SUBTOTAL'
ACROSS COUNTRY_1  AS ACROSS-TITLE
WHERE TYPE EQ 'COUPE'
HEADING
"HEADING"
FOOTING BOTTOM
"FOOTING"
ON TYPE_1 SUBHEAD
"SUBHEAD"
ON TYPE_1 SUBFOOT
"SUBFOOT"
ON TABLE COLUMN-TOTAL AS GRANDTOTAL AND ROW-TOTAL  AS ROWTOTAL
ON TABLE SUBHEAD
"TABHEADING"
ON TABLE SUBFOOT
"TABFOOTING"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET PAGE-NUM OFF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,PAGESIZE='A4',PAGECOLOR=WHITE,ORIENTATION=LANDSCAPE,HEADALIGN=INTERNAL,$
 
TYPE=TABHEADING ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREEN ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=HEADING    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREY  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=TITLE      ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=RED   ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=ACROSSTITLE,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=PINK  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=ACROSS     ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=SILVER,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=REPORT     ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=WHITE ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBHEAD    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=CYAN  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBFOOT    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=VIOLET,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBTOTAL   ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=YELLOW,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=GRANDTOTAL ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=ORANGE,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=FOOTING    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREY  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=TABFOOTING ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=BLUE  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
 
END
-EXIT  

Thanks Mickey!

Nubi,

Take a gold star!!

Here we have a learner who is prepared to take on the language and try and understand it better by pulling it apart and seeing what does what, rather than "asking the audience" without the most basic attempts being made.

Take a bow whilst other newbies follow your lead (hopefully).

T

Tony,

It just brings tears of joy to your eyes doesn't it?

Mickey,

It would do if I wasn't such a callous, insensitive maniac

Really though, it does give some hope when you see that someone is prepared, not only to help themselves a little more, but to share the pains of learning a new language with others.

T

i like to offer what little i can

nubi,
I'm currently in a mentoring role helping someone learn WebFOCUS reporting elements. Your colorful exercise was instantly helpful!
Thanks.

I agree that this is a great idea and would like to see you expand this as much as possible. Even us long time WebFOCUS users need to be reminded of things every now and then and identifying elements in a report is definitely one of them.

Perhaps Gerry would consider adding it into the IBISAMP folder for new releases? or even take the idea into the "help" files for a more graphical example? I'm thinking of printing it out and holding it in my style guide.

Marilyn,

It's good to post on the helpfulness of this subject. It's what is needed sometimes to encourage new users to have the belief that what they have to contribute is, indeed, most valuable. Thank you....

T

I will try to expand it as a i learn it. Of course this code is now 'ours' so anyone who feels they can improve upon it is very welcome to contribute...PDF and EXL2K outputs require a bit more code to look the same so ill endevour to get this added.

i appreciate the feedback; as Tony A says it certainly encourages me to share these things when i know that veterans, newbies and even those training others have found it useful

whilst im on the subject you can add:

 FOCEXEC = [any fex].fex,
 

to any line of the 'TYPE=' code to make that element drillable.

so

TYPE=SUBHEAD ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=CYAN ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$

becomes:

TYPE=SUBHEAD ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=CYAN ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,FOCEXEC=[any fex].fex,$

cool eh?

nubi, i hope you're coming to Summit.
and especially to Mickey's presentation and to the Focal Point tips & techniques session...
You might just start a new tradition..."Rookie of the Year"...
-S.

Hi Susannah, Im afraid not - i can't afford the trip over to the states as ive just moved house so will be skint all year!

have fun in texas!

well, i'm not at all sure what skink means..
update your profile and tell us where in the world you are, would you?
You may be awarded in absentia

I support Tony's Star....

skint means broke, buying a place of your own is an expensive business so can't afford any hols this year....

and i see that it's in Tennesse and not Texas as i thought, for some reason thought it was in Dallas?!?

I thought it was in Dallas as well...
Does anybody know where next year's summit is going to be held?

On the Stylesheet... I cluttered up Nubi's very nice template. I thought to add some cool stuff with LINE= paramter with a URL Link (thought to link to my business as an advertising freebie hah hah... but thought better of it, so used the good ol' google instead) and TYPE=DATA with conditional styling and of course, now the lay-out is not so nice. But hey, maybe some newbie will get the picture...

DEFINE FILE CAR
TYPE_1/A10=IF TYPE EQ 'COUPE' THEN 'REPORT' ELSE IF TYPE EQ 'SEDAN' THEN 'DATA' ELSE 'NADA';
COUNTRY_1/A10=IF COUNTRY EQ 'ITALY' THEN 'ACROSS' ELSE 'NADA';
END
 
TABLE FILE CAR
SUM RCOST
BY TYPE_1 AS TITLE SUBTOTAL AS 'BY SUBTOTAL'
ACROSS COUNTRY_1  AS ACROSS-TITLE
WHERE TYPE EQ 'COUPE' OR 'SEDAN'
HEADING
"HEADING"
"Heading Line 2"
FOOTING BOTTOM
"FOOTING"
ON TYPE_1 SUBHEAD
"SUBHEAD"
ON TYPE_1 SUBFOOT
"SUBFOOT"
ON TABLE COLUMN-TOTAL AS GRANDTOTAL AND ROW-TOTAL  AS ROWTOTAL
ON TABLE SUBHEAD
"TABHEADING"
ON TABLE SUBFOOT
"TABFOOTING"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET PAGE-NUM OFF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,PAGESIZE='A4',PAGECOLOR=WHITE,ORIENTATION=LANDSCAPE,HEADALIGN=INTERNAL,$
 
TYPE=TABHEADING ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREEN ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=HEADING    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREY  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=HEADING    ,LINE=2,SIZE=9,URL='http://www.google.com',TARGET='_blank',$
TYPE=TITLE      ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=RED   ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=ACROSSTITLE,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=PINK  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=ACROSS     ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=SILVER,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=REPORT     ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=WHITE ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBHEAD    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=CYAN  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBFOOT    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=VIOLET,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBTOTAL   ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=YELLOW,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=GRANDTOTAL ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=ORANGE,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=FOOTING    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREY  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=TABFOOTING ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=BLUE  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=DATA       ,COLUMN=N2,STYLE=BOLD+ITALIC,WHEN=TYPE_1 EQ 'DATA',$
 
END
-EXIT  

cool stuff anatess, im going to think of a way of incorporating the DATA statement into the code so it somehow displays the difference between DATA and REPORT. im not sure how yet but thanks for the contribution.

Added TYPE=RECAP in light blue. Although, more often than not you'd put a recap in a subfoot.

DEFINE FILE CAR
TYPE_1/A10=IF TYPE EQ 'COUPE' THEN 'REPORT' ELSE IF TYPE EQ 'SEDAN' THEN 'DATA' ELSE 'NADA';
COUNTRY_1/A10=IF COUNTRY EQ 'ITALY' THEN 'ACROSS' ELSE 'NADA';
END
 
TABLE FILE CAR
SUM RCOST
BY TYPE_1 AS TITLE SUBTOTAL AS 'BY SUBTOTAL'
BY TYPE NOPRINT
ACROSS COUNTRY_1  AS ACROSS-TITLE
ON TYPE RECAP ROWTOTAL_IN_EUROS/D12.2 = RCOST * 1.35;
WHERE TYPE EQ 'COUPE' OR 'SEDAN'
HEADING
"HEADING"
"Heading Line 2"
FOOTING BOTTOM
"FOOTING"
ON TYPE_1 SUBHEAD
"SUBHEAD"
ON TYPE_1 SUBFOOT
"SUBFOOT"
ON TABLE COLUMN-TOTAL AS GRANDTOTAL AND ROW-TOTAL  AS ROWTOTAL
ON TABLE SUBHEAD
"TABHEADING"
ON TABLE SUBFOOT
"TABFOOTING"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET PAGE-NUM OFF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,PAGESIZE='A4',PAGECOLOR=WHITE,ORIENTATION=LANDSCAPE,HEADALIGN=INTERNAL,$
 
TYPE=TABHEADING ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREEN ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=HEADING    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREY  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=HEADING    ,LINE=2,SIZE=9,URL='http://www.google.com',TARGET='_blank',$
TYPE=TITLE      ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=RED   ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=ACROSSTITLE,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=PINK  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=ACROSS     ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=SILVER,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=REPORT     ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=WHITE ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBHEAD    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=CYAN  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBFOOT    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=VIOLET,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=SUBTOTAL   ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=YELLOW,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=GRANDTOTAL ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=BLACK,BACKCOLOR=ORANGE,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=FOOTING    ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=GREY  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=TABFOOTING ,JUSTIFY=CENTER,STYLE=NORMAL,FONT=ARIAL,COLOR=WHITE,BACKCOLOR=BLUE  ,BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
TYPE=DATA       ,COLUMN=N2,STYLE=BOLD+ITALIC,WHEN=TYPE_1 EQ 'DATA',$
TYPE=RECAP      ,JUSTIFY=LEFT,STYLE=BOLD,FONT=ARIAL,COLOR=BLACK,BACKCOLOR='LIGHT BLUE',BORDER=LIGHT,BORDER-STYLE=SOLID,BORDER-COLOR=BLACK,$
END
-EXIT  

Thanks Anatess.
This one's a "keeper".

i think so too, the RECAP function is another one that i get mixed up with.

keep it coming guys!!