Hi All,

I want to repeat by Subhead section each page, I got the following code from forum. But when I use this code I am getting the subhead is repeating twice when BY records starts in new page. Please help me on this to resolve.

 TABLE FILE GGSALES
HEADING
"Page <TABPAGENO"
SUM
	DOLLARS AS ''
	BUDDOLLARS AS ''
AND COMPUTE ROWCNT/I9 = LAST ROWCNT + 1; NOPRINT

BY REGION NOPRINT
BY ST AS ''
BY CITY AS ''
BY STCD AS ''
BY PRODUCT AS ''
BY TOTAL ROWCNT NOPRINT

ON ROWCNT SUBHEAD
"Region: <REGION "
WHEN REGION NE LAST REGION OR TABPAGENO NE LAST TABPAGENO;

-*WHERE READLIMIT EQ 1000

ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
     PAGESIZE='Letter',
     LEFTMARGIN=0.250000,
     RIGHTMARGIN=0.250000,
     TOPMARGIN=0.250000,
     BOTTOMMARGIN=0.250000,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=ON,
     FONT='TIMES NEW ROMAN',
     SIZE=9,
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
TYPE=SUBHEAD, BY=6, BACKCOLOR=YELLOW,$
ENDSTYLE
END 

Thanks,
Kumaravel.M

This message has been edited. Last edited by: <Kathryn Henning>,

Hi Kumaravel,
The issue with this is nothing but the Margin you have added with the Portrait. So just try to increase the TopMargin or Bottom Margin, you will get the output as you expected.
I just tried increasing the Bottom Margin in the style code as follows:
BOTTOMMARGIN=0.550000,

and got the expected output.
Hope this helps you.

Thank you,
Arun

(belatedly, sorry)
If you don't want to change the margins, font size, etc, then COMPUTE a field to determine whether you want the subhead--instead of using OR in your WHEN.

 TABLE FILE GGSALES
HEADING
"Page <TABPAGENO"
SUM
	DOLLARS AS ''
	BUDDOLLARS AS ''
AND COMPUTE ROWCNT/I9 = LAST ROWCNT + 1; NOPRINT
AND COMPUTE PRINTSUBHEAD/A2V=IF (REGION NE LAST REGION) OR TABPAGENO NE LAST TABPAGENO THEN 'ON' ELSE ' '; NOPRINT

BY REGION NOPRINT
BY ST AS ''
BY CITY AS ''
BY STCD AS ''
BY PRODUCT AS ''
BY TOTAL ROWCNT AS ' '

ON ROWCNT SUBHEAD
"Region: <REGION "
WHEN (PRINTSUBHEAD EQ 'ON' );

ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
     PAGESIZE='Letter',
     LEFTMARGIN=0.250000,
     RIGHTMARGIN=0.250000,
     TOPMARGIN=0.250000,
     BOTTOMMARGIN=0.250000,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=ON,
     FONT='TIMES NEW ROMAN',
     SIZE=9,
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
TYPE=SUBHEAD, BY=6, BACKCOLOR=YELLOW,$
ENDSTYLE
END