Hi,
I want to comibe the mutiple cells into single cell. Is that possible in HTML format?

TABLE FILE CAR
SUM
CAR AS '' DEALER_COST AS ''
OVER
COUNTRY AS '' RETAIL_COST AS ''
OVER
MODEL AS ''
COMPUTE BLANK1/A1=' '; AS ''
OVER
COMPUTE BLANK2/A1=' '; AS ''
COMPUTE BLANK3/A1=' '; AS ''
BY CAR NOPRINT
BY COUNTRY NOPRINT
BY MODEL NOPRINT

HEADING
"TEST REPORT 1"
"CAR <+0> DEALER COST"
"COUNTRY <+0> RETAIL COST"
"MODEL <+0> "

ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON,
FONT='ARIAL', SIZE=8,GRID=ON,
$
TYPE=HEADING, HEADALIGN=BODY,$
TYPE=HEADING, LINE=1, COLSPAN=2, $
ENDSTYLE
END

This message has been edited. Last edited by: Kerry,

Which cells do you want to combine ?

Hi,
I want to combine CAR,COUNTRY,MODEL as one cell and DEALER_COST and RETAIL_COST as one cell.Is that possible within HTML using the FOCUS Code?

Regards,
MSAM

This seems to work.

DEFINE FILE CAR
 HEAD1/A50 = 'Car<BR>Country<BR>Model';
 HEAD2/A50 = '<BR>Dealer Cost<BR>Retail Cost';
END
-*
TABLE FILE CAR
SUM
CAR AS '' DEALER_COST AS ''
OVER
COUNTRY AS '' RETAIL_COST AS ''
OVER
MODEL AS ''
COMPUTE BLANK1/A1=' '; AS ''
OVER
COMPUTE BLANK2/A1=' '; AS ''
COMPUTE BLANK3/A1=' '; AS ''
BY CAR NOPRINT
BY COUNTRY NOPRINT
BY MODEL NOPRINT
HEADING
"TEST REPORT 1"
"<HEAD1<+0><HEAD2"
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON,
FONT='ARIAL', SIZE=8,GRID=ON,
$
TYPE=HEADING, HEADALIGN=BODY,$
TYPE=HEADING, LINE=1, COLSPAN=2, $
ENDSTYLE
END

Hi Dan,
Thanks for the update. I really appreciate that. Is there a way similiar to display multiple data values as single cell.
I mean the CAR,COUNTRY,MODEL values should be clubbed as a Single cell .

Regards,
MSAM

I think merging vertical data cells will be very difficult. You can turn off the cell dividers in the StyleSheet with GRID=OFF.

This is probably not what your looking for but....

DEFINE FILE CAR
 Col1/A58 = CAR | '<BR>' | COUNTRY | '<BR>' | MODEL ;
 Col2/A22 = FTOA(DEALER_COST,'(F7C)','A9') | '<BR>' | FTOA(RETAIL_COST,'(F7C)','A9') ;
END
TABLE FILE CAR
SUM
Col1 AS 'CAR<BR>COUNTRY<BR>MODEL'
Col2 AS 'DEALER_CODE<BR>RETAIL_COST'
BY CAR NOPRINT
BY COUNTRY NOPRINT
BY MODEL NOPRINT

HEADING
"TEST REPORT 1"

ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON,
FONT='ARIAL', SIZE=8,GRID=ON,$
TYPE=DATA, COLUMN=P2, JUSTIFY=RIGHT, $
TYPE=HEADING, HEADALIGN=BODY,$
TYPE=HEADING, LINE=1, COLSPAN=2, $
ENDSTYLE
END

Waz, that sure looks like what msam's looking for... Lucky for msam, it's an HTML report.

Proved me wrong! Nice job Waz.

As Francis said, its an HTML report.

Just taking advantage of the output format.

Waz,
Thanks for the help. That is what I was looking for.

Regards,
MSAM