[SOLVED] Multiple Cells into Single cell in HTML format
Hi, I want to comibe the mutiple cells into single cell. Is that possible in HTML format?
TABLE FILE CAR SUM CAR AS '' DEALER_COST AS '' OVER COUNTRY AS '' RETAIL_COST AS '' OVER MODEL AS '' COMPUTE BLANK1/A1=' '; AS '' OVER COMPUTE BLANK2/A1=' '; AS '' COMPUTE BLANK3/A1=' '; AS '' BY CAR NOPRINT BY COUNTRY NOPRINT BY MODEL NOPRINT
ON TABLE SET PAGE NOLEAD ON TABLE SET STYLE * TYPE=REPORT, SQUEEZE=ON, FONT='ARIAL', SIZE=8,GRID=ON, $ TYPE=HEADING, HEADALIGN=BODY,$ TYPE=HEADING, LINE=1, COLSPAN=2, $ ENDSTYLE ENDThis message has been edited. Last edited by: Kerry,
March 02, 2010, 04:20 PM
Waz
Which cells do you want to combine ?
Waz...
Prod:
WebFOCUS 7.6.10/8.1.04
Upgrade:
WebFOCUS 8.2.07
OS:
Linux
Outputs:
HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!
March 03, 2010, 09:47 AM
<msam>
Hi, I want to combine CAR,COUNTRY,MODEL as one cell and DEALER_COST and RETAIL_COST as one cell.Is that possible within HTML using the FOCUS Code?
Regards, MSAM
March 03, 2010, 01:35 PM
Dan Satchell
This seems to work.
DEFINE FILE CAR
HEAD1/A50 = 'Car<BR>Country<BR>Model';
HEAD2/A50 = '<BR>Dealer Cost<BR>Retail Cost';
END
-*
TABLE FILE CAR
SUM
CAR AS '' DEALER_COST AS ''
OVER
COUNTRY AS '' RETAIL_COST AS ''
OVER
MODEL AS ''
COMPUTE BLANK1/A1=' '; AS ''
OVER
COMPUTE BLANK2/A1=' '; AS ''
COMPUTE BLANK3/A1=' '; AS ''
BY CAR NOPRINT
BY COUNTRY NOPRINT
BY MODEL NOPRINT
HEADING
"TEST REPORT 1"
"<HEAD1<+0><HEAD2"
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON,
FONT='ARIAL', SIZE=8,GRID=ON,
$
TYPE=HEADING, HEADALIGN=BODY,$
TYPE=HEADING, LINE=1, COLSPAN=2, $
ENDSTYLE
END
WebFOCUS 7.7.05
March 03, 2010, 01:42 PM
<msam>
Hi Dan, Thanks for the update. I really appreciate that. Is there a way similiar to display multiple data values as single cell. I mean the CAR,COUNTRY,MODEL values should be clubbed as a Single cell .
Regards, MSAM
March 03, 2010, 02:56 PM
Dan Satchell
I think merging vertical data cells will be very difficult. You can turn off the cell dividers in the StyleSheet with GRID=OFF.
WebFOCUS 7.7.05
March 03, 2010, 04:02 PM
Waz
This is probably not what your looking for but....
DEFINE FILE CAR
Col1/A58 = CAR | '<BR>' | COUNTRY | '<BR>' | MODEL ;
Col2/A22 = FTOA(DEALER_COST,'(F7C)','A9') | '<BR>' | FTOA(RETAIL_COST,'(F7C)','A9') ;
END
TABLE FILE CAR
SUM
Col1 AS 'CAR<BR>COUNTRY<BR>MODEL'
Col2 AS 'DEALER_CODE<BR>RETAIL_COST'
BY CAR NOPRINT
BY COUNTRY NOPRINT
BY MODEL NOPRINT
HEADING
"TEST REPORT 1"
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON,
FONT='ARIAL', SIZE=8,GRID=ON,$
TYPE=DATA, COLUMN=P2, JUSTIFY=RIGHT, $
TYPE=HEADING, HEADALIGN=BODY,$
TYPE=HEADING, LINE=1, COLSPAN=2, $
ENDSTYLE
END
Waz...
Prod:
WebFOCUS 7.6.10/8.1.04
Upgrade:
WebFOCUS 8.2.07
OS:
Linux
Outputs:
HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!
March 03, 2010, 04:10 PM
Francis Mariani
Waz, that sure looks like what msam's looking for... Lucky for msam, it's an HTML report.
Francis
Give me code, or give me retirement. In FOCUS since 1991
Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
March 03, 2010, 04:20 PM
Dan Satchell
Proved me wrong! Nice job Waz.
WebFOCUS 7.7.05
March 03, 2010, 04:56 PM
Waz
As Francis said, its an HTML report.
Just taking advantage of the output format.
Waz...
Prod:
WebFOCUS 7.6.10/8.1.04
Upgrade:
WebFOCUS 8.2.07
OS:
Linux
Outputs:
HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!
March 04, 2010, 09:33 AM
<msam>
Waz, Thanks for the help. That is what I was looking for.