I have four PDF reports that I'd like to combine with COMPOUND. They all have the same HEADING. I would like to use NOBREAK, but I do not want the HEADING of the next report to show up half way on the page - there is already a HEADING at the top of the page from the previous report. The four reports have a different number of columns each, so I'd rather not combine the data before creating a single PDF report.

As well, I would like to make the COMPOUND report flexible so that it does not matter how many reports are in the COMPOUND report. I thought I could OPEN the COMPOUND report at the top, run x number of reports and then CLOSE NOBREAK the COMPOUND report at the end with a dummy one-line report using this code:

SET COMPOUND = CLOSE NOBREAK
-RUN

TABLE FILE FUND
PRINT FUND_NAME NOPRINT
WHERE READLIMIT EQ 1

ON TABLE PCHOLD FORMAT PDF
END
-RUN

This works well, except I get a blank page at the end, which means the NOBREAK on the last report doesn't work.

Do all the reports have to be NOBREAK?

Is this all improved drastically in 7.6?

This message has been edited. Last edited by: Kerry,

Francis,

You soooooo need the 7.6 compound layout tool.

Exactly what you need for your current requirement but soooooo OTT for "standard" one follows one reporting

T

Francis,

I have one that I tricked...with a dummy at the end like yours...I did not put NOBREAK...on the last 2 reports and it worked. This is a 15 Report Compound Report.

I agree with Tony. Then you could use a Page Master for your headings and page numbering.

Wait...did I hear Tony recommending GUI???

Um, well, yes

But only for Francis to use

For me, I'm still getting the syntax requirements figured out so that I will not have too

T

Tony,

Used the Painter once to decipher the code, haven't used it since. I use an amper to determine whether the data needs multi-pages, to include the header page again, so, here's an example of a 3-tier PDF process, hand-coded.


FYI, IF you really need an example...

  -* File multi_page3.fex
-****************************************************
-MULTI_PAGE3
-****************************************************
-SET &HDR_PASS = 0;
SET HTMLARCHIVE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
UNITS=IN, $
SECTION=section1, LAYOUT=ON, METADATA='0.5^0.5^0.5^0.5', MERGE=OFF, ORIENTATION=PORTRAIT, PAGESIZE=Letter, $
PAGELAYOUT=1, NAME='Page layout 1', text='Page layout 1', TOC-LEVEL=1, BOTTOMMARGIN=0.0, TOPMARGIN=0.0, METADATA='0^0.5^0^0.5', $
-**************************************************************************************************************
-*                                                          LEFT   TOP               WIDTH HEIGHT
-**************************************************************************************************************
COMPONENT='report8', TEXT='report8', TOC-LEVEL=2, POSITION=(0.167 0.156), DIMENSION=(8.177 0.552),  METADATA='Z-INDEX: 100; LEFT: 0.167in; WIDTH: 8.177in; POSITION: absolute; TOP: 0.156in;  HEIGHT: 0.552in', $
COMPONENT='report1', TEXT='report1', TOC-LEVEL=2, POSITION=(0.140 0.923), DIMENSION=(4.250 6.700),  METADATA='Z-INDEX: 100; LEFT: 0.140in; WIDTH: 4.250in; POSITION: absolute; TOP: 0.923in;  HEIGHT: 6.700in', $
COMPONENT='report2', TEXT='report2', TOC-LEVEL=2, POSITION=(4.427 0.923), DIMENSION=(4.250 6.750),  METADATA='Z-INDEX: 100; LEFT: 4.427in; WIDTH: 4.250in; POSITION: absolute; TOP: 0.923in;  HEIGHT: 6.750in', $
PAGELAYOUT=2, NAME='Page layout 2', text='Page layout 2', TOC-LEVEL=1, BOTTOMMARGIN=0.0, TOPMARGIN=0.0, METADATA='0^0.5^0^0.5', $
COMPONENT='report9', TEXT='report9', TOC-LEVEL=2, POSITION=(0.167 0.156), DIMENSION=(8.177 0.552),  METADATA='Z-INDEX: 100; LEFT: 0.167in; WIDTH: 8.177in; POSITION: absolute; TOP: 0.156in;  HEIGHT: 0.552in', $
COMPONENT='report3', TEXT='report3', TOC-LEVEL=2, POSITION=(0.167 0.923), DIMENSION=(4.250 6.700),  METADATA='Z-INDEX: 103; LEFT: 0.167in; WIDTH: 4.250in; POSITION: absolute; TOP: 3.350in;  HEIGHT: 6.700in', $
COMPONENT='report5', TEXT='report5', TOC-LEVEL=2, POSITION=(4.427 0.923), DIMENSION=(4.250 6.750),  METADATA='Z-INDEX: 104; LEFT: 4.427in; WIDTH: 4.250in; POSITION: absolute; TOP: 3.350in;  HEIGHT: 6.750in', $
PAGELAYOUT=3, NAME='Page layout 3', text='Page layout 3', TOC-LEVEL=1, BOTTOMMARGIN=0.0, TOPMARGIN=0.0, METADATA='0^0.5^0^0.5', $
COMPONENT='report10', TEXT='report10', TOC-LEVEL=2, POSITION=(0.167 0.156), DIMENSION=(8.177 0.552),  METADATA='Z-INDEX: 100; LEFT: 0.167in; WIDTH: 8.177in; POSITION: absolute; TOP: 0.156in;  HEIGHT: 0.552in', $
COMPONENT='report7', TEXT='report7', TOC-LEVEL=2, POSITION=(0.140 0.923), DIMENSION=(4.250 6.000),  METADATA='Z-INDEX: 100; LEFT: 0.140in; WIDTH: 4.250in; POSITION: relative; TOP: 0.923in;  HEIGHT: 6.000in', $
COMPONENT='report4', TEXT='report4', TOC-LEVEL=2, POSITION=(4.427 0.923), DIMENSION=(3.250 6.500),  METADATA='Z-INDEX: 100; LEFT: 4.427in; WIDTH: 3.250in; POSITION: relative; TOP: 0.923in;  HEIGHT: 6.500in', $
COMPONENT='report6', TEXT='report6', TOC-LEVEL=2, POSITION=(0.538 9.479), DIMENSION=(6.875 0.938),  METADATA='Z-INDEX: 100; LEFT: 0.538in; WIDTH: 6.875in; POSITION: absolute; TOP: 9.479in;  HEIGHT: 0.938in', $
END
SET COMPONENT='report8'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt_main_hdr
SET COMPONENT='report1'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt00012
SET COMPONENT='report2'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt00016
SET COMPONENT='report9'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt_main_hdr
SET COMPONENT='report3'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt00013
SET COMPONENT='report5'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt00017
SET COMPONENT='report10'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt_main_hdr
SET COMPONENT='report7'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt00015
SET COMPONENT='report4'
-*component_type report
-INCLUDE &SHRPATH.EVAL/xrpt00014
SET COMPONENT='report6'
-*component_type report
-INCLUDE &SHRPATH.EVAL/last_page_footer
COMPOUND END
-EXIT

Spot on Tom, exactly what I've already done

Used once then thrown away - lol

I now just play with the settigns to comprehend exactly how the interact!

T

OK, so now that you both (Tom/Tony) have gone down the road to decypher the code for coordinated reports (which IBI has not documented), which one of you is going to write an article explaining to the rest of us old school coders how to make one from scratch?

Sounds like another 'POW' presentation for Summit that might get some interest.

TONY!!!!!

I tried to figure out how to use the code the tool produced for 'Page # of Pages' in the compound report for one I had hand coded and didn't have any luck...I was hoping for some documentation.

Thanks everyone! That was amusing. I can't wait to jump into the 7.6.* end of the pool.

Tom, I'll give your code a try.

Cheers,

Thanks Tom, (now to be known as "slopey" as in shoulders!) but I won't volunteer for this until I've had more time to play. Summit this year for me will be purely for learning and networking - oh, and socialising (not the same as networking )

T

OK,

Definitely don't want to known as "Slopey" , so, maybe we can co-ordinate a DOC. Haven't attended a SUMMIT, only FUSE's, and that was last century!!!

Praire, apples and oranges: Adobe just takes over; you can do section page settings in Adobe, or, hard-code the page-number in each program, since, in my example, I KNOW the number of pages. Now, with 15 reports, creating a BOOK, different story. Could be detail, could be summary; again, Adobe takes over.

"MAYBE IBI HAS A SOLUTION!!!!"

Oh well, just noticed that Tom's code is of the newfangled variety, I'll have to wait until next year for that.

Francis...did my trick not work for you?

Here's the code for the Page of Page if Tom and Tony want to tackle.

PAGELAYOUT=ALL, NAME='Page Master', $
OBJECT=STRING, NAME='text1', TEXT='Page ibi-page-number/ of ibi-total-pages/', POSITION=(6.563 0.625), MARKUP=ON, WRAP=ON, DIMENSION=(1.354 0.625), font='ARIAL', color=RGB(0 0 0), size=10, $

Praire,

Will test this week, let everyone know...

Francis, sorry!!!
If Prarie's code doesn't work for you, send me a post with the code, I'll load your version of WF and try to assist.

Pretty good at PDF stuff....

Prarie,

Your trick is the same as my trick. I've tried this with and without NOBREAK.

It might simply be how I coded the dummy report at the end.

Here's my code:

-SET &ECHO = 'ALL';

SET MSG = ON
-RUN

SET HOLDLIST    = PRINTONLY
SET ASNAMES     = ON
SET HOLDFORMAT  = ALPHA
SET ALL         = ON

SET PRINTPLUS   = ON
SET PAGE        = NOPAGE
SET CENT-ZERO   = ON
-RUN

SET COMPOUND = OPEN
-RUN

-*-- Report 1 ----------------------------------------------
TABLE FILE GGSALES
SUM
UNITS/D15
DOLLARS/D15
BUDUNITS/D15
BUDDOLLARS/D15

BY REGION                     NOPRINT
BY CATEGORY
BY PRODUCT

ON REGION                     SUBHEAD
"<REGION"
" "
ON REGION                     SUBTOTAL AS 'Total for'
ON TABLE                      SUBTOTAL AS 'Total'

HEADING
"Product Sales and Budget Details"
" "

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
UNITS=IN, PAGESIZE=LETTER, ORIENTATION=PORTRAIT, SQUEEZE=ON,
LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=1.0, $
TYPE=REPORT    , GRID=OFF, FONT=ARIAL, SIZE=9, TOPGAP=0.02, BOTTOMGAP=0.04, $
TYPE=HEADING   , STYLE=BOLD,  $
TYPE=HEADING   , LINE=1, SIZE=11, POSITION=(0.5 1.5),$
TYPE=HEADING   , IMAGE=crmrep1.jpg, IMAGEALIGN=TOP, IMAGEBREAK=ON, $
TYPE=TITLE     , STYLE=BOLD, $
TYPE=SUBHEAD   , STYLE=BOLD, COLOR=RGB(2 99 108), $
TYPE=SUBTOTAL  , STYLE=BOLD, $
TYPE=GRANDTOTAL, STYLE=BOLD, $
ENDSTYLE
END
-RUN

-*-- Report 2 ----------------------------------------------
TABLE FILE GGSALES
SUM
UNITS/D15
DOLLARS/D15
BUDUNITS/D15
BUDDOLLARS/D15

BY REGION                     NOPRINT
BY CATEGORY
BY PRODUCT

ON REGION                     SUBHEAD
"<REGION"
" "
ON REGION                     SUBTOTAL AS 'Total for'
ON TABLE                      SUBTOTAL AS 'Total'

WHERE CATEGORY EQ 'GOODFORYOU'

HEADING
"Product Sales and Budget Details"
" "

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
UNITS=IN, PAGESIZE=LETTER, ORIENTATION=PORTRAIT, SQUEEZE=ON,
LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=1.0, $
TYPE=REPORT    , GRID=OFF, FONT=ARIAL, SIZE=9, TOPGAP=0.02, BOTTOMGAP=0.04, $
TYPE=HEADING   , STYLE=BOLD,  $
TYPE=HEADING   , LINE=1, SIZE=11, POSITION=(0.5 1.5),$
TYPE=HEADING   , IMAGE=crmrep1.jpg, IMAGEALIGN=TOP, IMAGEBREAK=ON, $
TYPE=TITLE     , STYLE=BOLD, $
TYPE=SUBHEAD   , STYLE=BOLD, COLOR=RGB(2 99 108), $
TYPE=SUBTOTAL  , STYLE=BOLD, $
TYPE=GRANDTOTAL, STYLE=BOLD, $
ENDSTYLE
END
-RUN

SET COMPOUND = CLOSE
-RUN

-*-- Dummy closing report ----------------------------------
TABLE FILE GGSALES
PRINT
PRODUCT NOPRINT

WHERE RECORDLIMIT EQ 1
WHERE READLIMIT EQ 1

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
UNITS=IN, PAGESIZE=LETTER, ORIENTATION=PORTRAIT, SQUEEZE=ON,
LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=1.0, $
ENDSTYLE
END
-RUN

Francis,

Well, I did the following:

1) Commented out -*SET COMPOUND = OPEN
2) For the 1st report - ON TABLE PCHOLD FORMAT PDF OPEN
3) For the 2nd report - WHERE CATEGORY NE 'GOODFORYOU'
4) For the 2nd report - ON TABLE PCHOLD FORMAT PDF CLOSE
5) Skipped the DUMMY report

OUTPUT: 4 pages Heading on each page (don't have the jpg)

Comments:

If you want to make this dynamic, set a counter for first, last, create &OPN_CLS, and pass them.

ON TABLE PCHOLD FORMAT PDF &OPN_CLS

I do this all the time with compound PDF's AND EXCEL stuff.

The only reason I use COMPOUND, i.e., the example I gave, is if the client wants side-by-side reports/graphs or,
2 reports are small, 2 are large on 3 pages, basically, data driven.

Hope this helps...


EDIT1: Report 2 had zero records with EQ
EDIT2: Sorry: Whenever I include an image in the heading, I use:
HEADING
" "
" "
" "
"Product Sales and Budget Details"
" "

then in STYLE:

TYPE=HEADING , IMAGE=crmrep1.jpg, POSITION=(0.5 1.5),$

I try to give it enough room for display...

This message has been edited. Last edited by: Tom Flynn,

Tom,

I purposely wanted to have the second report not have any data. The idea is that I want a program that is flexible - I don't know how many of the several reports will have data, therefore I can't use PCHOLD FORMAT PDF OPEN either, because I don't know which one will be the first report.

I have assumed that SET COMPOUND=OPEN and PCHOLD FORMAT PDF OPEN do exactly the same thing, but previous postings seem to suggest otherwise.

Thanks,

Francis,

Exactly, If, I leave the test as EQ, you get 2 pages, NE, gets 4. I thought that's what you were looking for...

Again, setting a counter/value for the 1st and last, even if being selected from a list, will allow you to do this..

When the middle report produces no data, I have the first report with two pages and the last dummy report with one blank page. I was hoping to tack the last dummy report to the bottom of the page without generating a blank page.

Francis,

You are so creative, you'll figure something out, like:

1) writing the fex's selected to a file and reading them in to execute
2) Within your HTML, setting a value for the first and last
3) giving each report a number and getting FST. and LST.
4) creating HOLD files and branching on &LINES (pain, I know, BUT...)

I am positive something will come to you...

This message has been edited. Last edited by: Tom Flynn,

Thanks Tom.

Francis,
What did you end up doing to get around this? I am in the same situation, blank page at the end of the report due to a dummy table. The user can select how many reports to run in the compound report. It would work perfectly if I could just get rid of the darn blank page at the end on one of the user selected options.

As Tony mentioned in November 2007, this is better accomplished with the v7.6 Compound Layout tool. The client that I originally tried to solve the problem for has not yet upgraded so they're living with the blank page for now.

Look into "Creating Reports With the Document Composer" and "Creating a Compound Layout Report" in the v7.6 documentation.

I had one similar to this recently when the new compound tool wasn't so useful as the old syntax. The user needed a multi page report where some sections just wouldn't exist on occasion. As they used the document in meetings for discussion on project direction etc. I sold them the idea of having a blank notes page with all the project details in a dummy heading and footing and the oft used "this page is intentionally left blank". They went for it and have found it very useful.

The advantage of course was the "blank" notes page at the end is always present and therefore I could code correctly.

Might this be an option for you?

T

Thanks. I somehow got it to work by including set compound=close in a variable. I'll look into that in the future.