Got stuck again,
So I got this table :

COUNTRY SALES
ENGLAND 12000
FRANCE 0
ITALY 30200
JAPAN 78030
W GERMANY 88190

COUNTRY DEALER_COST
ENGLAND 37,853
FRANCE 4,631
ITALY 41,235
JAPAN 5,512
W GERMANY 54,563

need to merge the two report so it comes out like this in HTML:
-********************************
Page 1.
COUNTRY SALES
ENGLAND 12000

COUNTRY DEALER_COST
ENGLAND 37,853
-********************************
Page 2.
COUNTRY SALES
FRANCE 0

COUNTRY DEALER_COST
FRANCE 4,631
-********************************
Page 3.
COUNTRY SALES
ITALY 30200

COUNTRY DEALER_COST
ITALY 41,235
-********************************
Page 4.
COUNTRY SALES
JAPAN 78030

COUNTRY DEALER_COST
JAPAN 5,512
-********************************
Page 5.
COUNTRY SALES
W GERMANY 88190

COUNTRY DEALER_COST
W GERMANY 54,563
-********************************

Can anyone know how to do this?

Thanks in advance....
Sunil

This message has been edited. Last edited by: Kerry,

Of course this is an example, so it will need to be adjusted for your real situation, but for the example given, it works. And it's not about merging the data, but about how to do the report, so I just used the one datasource, CAR.

TABLE FILE CAR
SUM   SALES NOPRINT
      DEALER_COST NOPRINT
BY    COUNTRY NOPRINT

ON    COUNTRY SUBHEAD
"COUNTRY<+0>SALES"
"<COUNTRY<SALES"
" "
"COUNTRY<+0>DEALER_COST"
"<COUNTRY<DEALER_COST"
" "
HEADING
"-****************************************"
"Page <TABPAGENO<+0>."
ON COUNTRY PAGE-BREAK
ON TABLE SET HEADALIGN INTERNAL
ON TABLE NOTOTAL
ON TABLE SET STYLE *
$
TYPE=REPORT, FONT='VERDANA', SIZE=9, COLOR='BLACK', STYLE=NORMAL, GRID=OFF,$
TYPE=SUBHEAD, LINE=1, OBJECT=TEXT, ITEM=1, COLOR='WHITE', BACKCOLOR='MAROON', WIDTH=1.2, STYLE=BOLD,$
TYPE=SUBHEAD, LINE=1, OBJECT=TEXT, ITEM=2, COLOR='WHITE', BACKCOLOR='BLUE', WIDTH=1.2, STYLE=BOLD,$
TYPE=SUBHEAD, LINE=4, OBJECT=TEXT, ITEM=1, COLOR='WHITE', BACKCOLOR='MAROON', WIDTH=1.2, STYLE=BOLD,$
TYPE=SUBHEAD, LINE=4, OBJECT=TEXT, ITEM=2, COLOR='WHITE', BACKCOLOR='BLUE', WIDTH=1.2, STYLE=BOLD,$
TYPE=SUBHEAD, LINE=2, OBJECT=FIELD, ITEM=1, WIDTH=1.2,$
TYPE=SUBHEAD, LINE=2, OBJECT=FIELD, ITEM=2, WIDTH=1.2,$
TYPE=SUBHEAD, LINE=5, OBJECT=FIELD, ITEM=1, WIDTH=1.2,$
TYPE=SUBHEAD, LINE=5, OBJECT=FIELD, ITEM=2, WIDTH=1.2,$
ENDSTYLE
END

Hope this helps ...

Thanks... It works

Sunil