Does webfocus provide a capability to maintain security groups in batch, as opposed to 1-by-1 maintenance in the online interface? If so, would a person who has security to add users online (domain admin) have the same rights for batch? If not, has anyone done a custom solution and was it easy to do? We're moving from 5.3.4 to 7.1.4 in a few weeks.

It's quite simple to do using MODIFY. Code your connection string to give yourself write access to the repository. Files are WF_% etc

Here's one that allows you to copy users so they have the same groups.

-* File usercopy.fex
-SET &DUMMY = &SOURCE.(FIND USERID IN WF_MRUSERS).Source Userid. ;
-SET &DUMMY = &TARGET.(FIND USERID IN WF_MRUSERS).Target Userid. ;
-SET &DUMMY = &OPTION.(View,Copy Delete first,Copy no Del,Delete from Target) ;

-IF &OPTION OMITS 'Delete' THEN GOTO NO_DELETE;

TABLE FILE WF_USRGRPTB
PRINT USERID GROUPID
IF USERID EQ '&TARGET'
ON TABLE HOLD
END
-RUN
MODIFY FILE WF_USRGRPTB

FIXFORM FROM HOLD
GOTO C001
CASE C001
MATCH USERID GROUPID
ON NOMATCH REJECT
ON MATCH DELETE
ENDCASE
DATA ON HOLD
END
-RUN

-NO_DELETE


-IF &OPTION OMITS 'Copy' THEN GOTO NO_COPY;

DEFINE FILE WF_USRGRPTB
NEW_USERID/A128V = '&TARGET' ;
END
TABLE FILE WF_USRGRPTB
HEADING
" Groups for &SOURCE "
PRINT NEW_USERID GROUPID ISGRPADMIN
IF USERID EQ '&SOURCE'
ON TABLE HOLD
END
-RUN
MODIFY FILE WF_USRGRPTB
COMPUTE
NEW_USERID/A128V = ;
FIXFORM FROM HOLD
GOTO C001
CASE C001
COMPUTE
USERID = NEW_USERID ;
MATCH USERID GROUPID
ON NOMATCH INCLUDE
ON MATCH REJECT
ENDCASE
DATA ON HOLD
END
-RUN

-NO_COPY

-TYPE WEBFOCUS CGIVAR IBIWF_mreports=FRAME
-TYPE WEBFOCUS CGIVAR IBIWF_mrcolumns=2
TABLE FILE WF_USRGRPTB
HEADING
" Groups for Source &SOURCE "
PRINT GROUPID ISGRPADMIN
IF USERID EQ '&SOURCE'
END
-RUN
TABLE FILE WF_USRGRPTB
HEADING
" Groups for Target &TARGET "
PRINT GROUPID ISGRPADMIN
IF USERID EQ '&TARGET'
END
-RUN

I'm curious about a couple of things.

1) What does

-SET &DUMMY = &SOURCE.(FIND USERID IN WF_MRUSERS).Source Userid. ;
-SET &DUMMY = &TARGET.(FIND USERID IN WF_MRUSERS).Target Userid. ;
-SET &DUMMY = &OPTION.(View,Copy Delete first,Copy no Del,Delete from Target) ;

do?

2) WF_USRGRPTB - Is this a Master you created? Are we not talking about MRE? If so, aren't the users in an HTML file (user.htm in basedir) and not in the "repository"? (The repository is for ReportCaster schedules)

Thanks,

Francis.

1. We use the amper auto prompt facility. This just allows us to put all the prompts together and make sure they appear in the order we want.

2. There are 2 repositories for the MRE mre and reportcaster. Check client administration menu for their locations they can be focus, oracle or sequel server.

The masters are created via synonym tool in the usual way after setting up the correct connection.

FILENAME=WF_MRUSERS, SUFFIX=SQLMSS , $
SEGMENT=WF_MRUSERS, SEGTYPE=S0, $
FIELDNAME=USERID, ALIAS=USERID, USAGE=A128V, ACTUAL=A128V, $
FIELDNAME=PASSWORD, ALIAS=PASSWORD, USAGE=A128V, ACTUAL=A128V,
MISSING=ON, $
FIELDNAME=LOGINNAME, ALIAS=LOGINNAME, USAGE=A128V, ACTUAL=A128V, $
FIELDNAME=USERNAME, ALIAS=USERNAME, USAGE=A255V, ACTUAL=A255V,
MISSING=ON, $
FIELDNAME=EMAIL, ALIAS=EMAIL, USAGE=A64V, ACTUAL=A64V,
MISSING=ON, $
FIELDNAME=ROLEID, ALIAS=ROLEID, USAGE=A48V, ACTUAL=A48V, $
FIELDNAME=PROPERTIES, ALIAS=PROPERTIES, USAGE=A255V, ACTUAL=A255V,
MISSING=ON, $
FIELDNAME=ISACTIVE, ALIAS=ISACTIVE, USAGE=A1, ACTUAL=A1, $
MISSING=ON, $

SEGNAME=WF_MRUSERS, TABLENAME=mrrealmdb.realmuser.WF_MRUSERS,
CONNECTION=MREREPOS, KEYS=1, $

If your security repository is held in an SQL source then using John's method should suit, if not then you need to define your own process depending upon the repository used.

As Francis mentioned above, the standard MRE security repository is HTML based. To achieve bulk update / loading of Users you would have to define your own process unless someone else on the Forum has already achieved this and is willing to share their solution with you.

My current client uses Active Directory and I have written several VB Scripts that connect Users into Group and Role memberships using the IB supplied VBS files as a model.

T

quote:

There are 2 repositories for the MRE mre and reportcaster

- What version of WebFOCUS are you talking about?

Running WF 7.1.3.

All the reports in the domains/users are still done via html files but the user - group - domain relationship is modelled in sqlserver.

This is set up in client administration under mre security authetication/authorization.

Thank you, hammo1j. This is interesting, I will have to look it up.