OK... Is there a way to adjust the GAP for data in such a way that MS Word does the paragraph spacing (Before and After) so that it is not applied to the middle of the paragraph?

Run the following code and "select all" in the resultant PDF to see that the GAP is applied to all the lines in the 'McGuyver/A800" field. I need that field to be treated as a single paragraph with the gap applied before and after it - not to the "middle lines" of the "paragraph.

You pointers are greatly appreciated.

DEFINE FILE CAR
McGuyver/A800 WITH COUNTRY = 'Ford Motor Company: Ask any fashionista, 
and she will tell you: Don’t even think about wearing those chandelier earrings 
with shorts and tennis shoes. No way. There are, after all, certain rules that 
apply to fashion and accessories. Ask Earl Lucas, exterior design manager for the 
2010 Taurus, and he’ll tell you those same accessorizing rules apply even if 
you’re designing a sophisticated sedan. Just like a person, 
every car has a personality and an image to convey, says the former jewelry designer. 
The "accessories," which in this case are the headlamps of the 2010 Ford Taurus, 
must be designed and detailed to project the proper image. The Taurus is a confident, 
well-balanced car. It has the jewelry to match.' ; 
END
TABLE FILE CAR 
PRINT MacGyver COUNTRY
BY CAR 
WHERE COUNTRY EQ 'ENGLAND'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET PAGE OFF
ON TABLE SET STYLE *
 ORIENTATION=PORTRAIT, UNITS=IN, PAGESIZE='LETTER', SQUEEZE=ON, GRID=OFF,
 LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=0.25,$
 TYPE=REPORT, FONT=ARIAL, SIZE=9, STYLE=NORMAL, TOPGAP=.05, BOTTOMGAP=.05,$
 TYPE=REPORT, COLUMN=MacGyver, WRAP = 4.0,$
ENDSTYLE
END
-* Source: http://www.at.ford.com/news/cn...nhancesAnOutfit.aspx

Thanks,
Doug

This message has been edited. Last edited by: Doug,

I would suggest:

  
DEFINE FILE CAR
McGuyver/A800 WITH COUNTRY = 'Ford Motor Company: Ask any fashionista, and she will tell you: Don’t even think about wearing those chandelier earrings with shorts and tennis shoes. No way. There are, after all, certain rules that apply to fashion and accessories. Ask Earl Lucas, exterior design manager for the 2010 Taurus, and he’ll tell you those same accessorizing rules apply even if you’re designing a sophisticated sedan. Just like a person, every car has a personality and an image to convey, says the former jewelry designer. The "accessories," which in this case are the headlamps of the 2010 Ford Taurus, must be designed and detailed to project the proper image. The Taurus is a confident, well-balanced car. It has the jewelry to match.' ; 
END
TABLE FILE CAR 
PRINT McGuyver COUNTRY
BY CAR
ON CAR SUBFOOT
" " 
WHERE COUNTRY EQ 'ENGLAND'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET PAGE OFF
ON TABLE SET STYLE *
 ORIENTATION=PORTRAIT, UNITS=IN, PAGESIZE='LETTER', SQUEEZE=ON, GRID=OFF,
 LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=0.25,$
 TYPE=REPORT, FONT=ARIAL, SIZE=9, STYLE=NORMAL, $
 TYPE=REPORT, COLUMN=McGuyver, WRAP = 4.0, $
 TYPE=SUBFOOT, SIZE=3, $
ENDSTYLE
END

Way to go Danny... I like it... It'll do the trick... I can use that... I guess I was lost in the "GAP"...

After looking at my requirement a bit deeper, I found that I needed more then that. The SUBFOOT was already used with a BORDER-TOP=MEDIUM to simulate / complete the frame around the entire report. So, I had to dig deeper and came up with the following code:

-* Build a variable for the McGuyver/A130 field
-SET &YADA = 'YADA YADA YADA ' ;
-REPEAT ENDOFYADA 3 TIMES ;
-SET &YADA = &YADA || (' ' | &YADA) ;
-ENDOFYADA
-* DEFINE the McGuyver field and a SORT field for the fianl aprt of the frame AND for an OVER field.
DEFINE FILE CAR
McGuyver/A130 WITH COUNTRY = '&YADA.EVAL' ;
SORT1/A1 = ' ' ;
END
TABLE FILE CAR
PRINT McGuyver AS '' COUNTRY AS '' OVER SORT1 AS ''
BY SORT1 NOPRINT
BY CAR AS ''
ON SORT1 SUBHEAD
"</1>Whatever... This simulates a report heading...</1>"
"Car <12>Notes <50>Country</1>"
ON SORT1 SUBFOOT
" "
WHERE COUNTRY EQ 'ENGLAND'
WHERE RECORDLIMIT EQ 2
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET PAGE OFF
ON TABLE SET STYLE *
 ORIENTATION=PORTRAIT, UNITS=IN, PAGESIZE='LETTER', SQUEEZE=ON, GRID=OFF,
 LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=0.25,$
 TYPE=REPORT, FONT=ARIAL, SIZE=9, STYLE=NORMAL, $
 TYPE=REPORT, COLUMN=CAR, WRAP = 0.95,$
 TYPE=REPORT, COLUMN=McGuyver, WRAP = 4.05,$
 TYPE=REPORT, COLUMN=COUNTRY, WRAP = 1.0,$
 TYPE=SUBFOOT, BORDER-TOP=MEDIUM, $
 TYPE=SUBHEAD, BORDER-TOP=MEDIUM, BORDER-LEFT=MEDIUM, BORDER-RIGHT=MEDIUM, STYLE=BOLD, JUSTIFY=LEFT,$
 TYPE=DATA, COLUMN=N2, BORDER-LEFT=MEDIUM,$
 TYPE=DATA, COLUMN=N4, BORDER-RIGHT=MEDIUM,$
 TYPE=DATA, COLUMN=N5, BORDER-RIGHT=MEDIUM,$
ENDSTYLE
END

Hey, it works... Thanks again Danny... I'll use the original solution someday (I'm sure)...

PS: I'm posting this because it contains some tips and techniques that someone should find useful someday...