Is there a way from the "ON TABLE SET STYLE *" section to force the column headers in a report to be appear in "Title Case" instead of "ALL CAPS"?

If so, can this be set for specific columns only?

This message has been edited. Last edited by: ColdWhiteMilk,

You can do this with AS

TABLE FILE CAR
PRINT CAR AS 'Car'
END

Sorry, I should have posted my code so that you could see why I need to do this in the stylesheet. I need to run the first part this way to get all of the column headers on the same line (the ACROSS column headers appear one line up from the rest). So when I do the PRINT * for the second part, it gives me all of the BY fields, and all of the ACROSS fields, but the ACROSS fields are just the field names from the hold file, even if I give them an alias.

TABLE FILE LIFECYCLEA
SUM
ROWTOT AS ''

BY FIELDA AS 'FIELDA'
BY FIELDB AS 'FIELDB'
BY FIELDC AS 'FIELDC'
BY FIELDD AS 'FIELDD'

ACROSS REJECTER
ACROSS-TOTAL AS 'TOTAL'

ON TABLE SET ASNAMES ON
ON TABLE HOLD
END

TABLE FILE HOLD
PRINT *

ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT

How about redefining the ACROSS field and using LCWORD?

  
DEFINE FILE CAR
COUNTRY_MIX/A100 = LCWORD(10, COUNTRY, COUNTRY_MIX);
END

TABLE FILE CAR
SUM  DEALER_COST AS ''

BY CAR   AS 'FIELDA'
BY MODEL AS 'FIELDB'
ACROSS COUNTRY_MIX
ACROSS-TOTAL AS 'TOTAL'
ON TABLE SET ASNAMES ON
ON TABLE HOLD
END

TABLE FILE HOLD
PRINT *
-*ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT

It is the "BY" fields that I can't get their column header to change to Title Case.

How about redefining the BY fields?

  
DEFINE FILE CAR
COUNTRY_MIX/A100 = LCWORD(10, COUNTRY, COUNTRY_MIX);
Car/A16 = CAR;
Model/A24 = MODEL;
END

TABLE FILE CAR
SUM  DEALER_COST AS ''

BY Car
BY Model
ACROSS COUNTRY_MIX
ACROSS-TOTAL AS 'Total'
ON TABLE SET ASNAMES ON
ON TABLE HOLD
END

TABLE FILE HOLD
PRINT *
-*ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT

Or you could add a TITLE to the fields in the master?

  
FIELD=CAR, ALIAS=CAR, FORMAT=A16, TITLE='Car',$  

The ASNAMES are staying all caps. Right?
Here is the syntax from the help file.

SET ASNAMES = [ON|OFF|MIXED|FOCUS]

So it looks like you need to do a

ON TABLE SET ASNAMES MIXED

I'm on 7.7.02 so I don't if this is avaialble in your version of Dev Studio.

Here is the sample

  
TABLE FILE CAR
SUM  DEALER_COST AS ''

BY CAR   AS 'Field1'
BY MODEL AS 'Field2'
ACROSS COUNTRY
ACROSS-TOTAL AS 'Total'
ON TABLE SET ASNAMES MIXED
ON TABLE HOLD
END

TABLE FILE HOLD
PRINT *
-*ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT

quote:

ON TABLE SET ASNAMES MIXED

You learn something new everyday.

Perfect! That is exactly what I needed.

Thank you.

Oh you do learn something new everyday.

Thanks