Is there a way from the "ON TABLE SET STYLE *" section to force the column headers in a report to be appear in "Title Case" instead of "ALL CAPS"?
If so, can this be set for specific columns only?This message has been edited. Last edited by: ColdWhiteMilk,
Production - 7.6.4 Sandbox - 7.6.4
August 10, 2011, 02:31 PM
Prarie
You can do this with AS
TABLE FILE CAR PRINT CAR AS 'Car' END
August 10, 2011, 02:54 PM
ColdWhiteMilk
Sorry, I should have posted my code so that you could see why I need to do this in the stylesheet. I need to run the first part this way to get all of the column headers on the same line (the ACROSS column headers appear one line up from the rest). So when I do the PRINT * for the second part, it gives me all of the BY fields, and all of the ACROSS fields, but the ACROSS fields are just the field names from the hold file, even if I give them an alias.
TABLE FILE LIFECYCLEA
SUM
ROWTOT AS ''
BY FIELDA AS 'FIELDA'
BY FIELDB AS 'FIELDB'
BY FIELDC AS 'FIELDC'
BY FIELDD AS 'FIELDD'
ACROSS REJECTER
ACROSS-TOTAL AS 'TOTAL'
ON TABLE SET ASNAMES ON
ON TABLE HOLD
END
TABLE FILE HOLD
PRINT *
ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT
Production - 7.6.4 Sandbox - 7.6.4
August 10, 2011, 03:39 PM
Mighty Max
How about redefining the ACROSS field and using LCWORD?
DEFINE FILE CAR
COUNTRY_MIX/A100 = LCWORD(10, COUNTRY, COUNTRY_MIX);
END
TABLE FILE CAR
SUM DEALER_COST AS ''
BY CAR AS 'FIELDA'
BY MODEL AS 'FIELDB'
ACROSS COUNTRY_MIX
ACROSS-TOTAL AS 'TOTAL'
ON TABLE SET ASNAMES ON
ON TABLE HOLD
END
TABLE FILE HOLD
PRINT *
-*ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT
It is the "BY" fields that I can't get their column header to change to Title Case.
Production - 7.6.4 Sandbox - 7.6.4
August 10, 2011, 04:12 PM
Mighty Max
How about redefining the BY fields?
DEFINE FILE CAR
COUNTRY_MIX/A100 = LCWORD(10, COUNTRY, COUNTRY_MIX);
Car/A16 = CAR;
Model/A24 = MODEL;
END
TABLE FILE CAR
SUM DEALER_COST AS ''
BY Car
BY Model
ACROSS COUNTRY_MIX
ACROSS-TOTAL AS 'Total'
ON TABLE SET ASNAMES ON
ON TABLE HOLD
END
TABLE FILE HOLD
PRINT *
-*ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT
Or you could add a TITLE to the fields in the master?
TABLE FILE CAR
SUM DEALER_COST AS ''
BY CAR AS 'Field1'
BY MODEL AS 'Field2'
ACROSS COUNTRY
ACROSS-TOTAL AS 'Total'
ON TABLE SET ASNAMES MIXED
ON TABLE HOLD
END
TABLE FILE HOLD
PRINT *
-*ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT