Hi All,

i got this PDF output problem. Report are in Lithuanian language the special letters are displayed wrong. In HTML and EXl2K output format report is displayed correctly.

Any hint will be usefull.

Thanks.

This message has been edited. Last edited by: Kerry,

quote:

usefull

Did you tried to SET the language?
E.g.
SET LANG = BAL

Usually this is due to an NLS configuration issue.

You must make sure that all WebFOCUS components are configured to use the same code pages (server and client)

well i tried to SET LANG to different languages makes no different result the same...
NLS are set to code page 1257 in both client and settings... Anything else??

There are specific font maps that are used when creating PDf output, so the characters that are needed may not be supported in the default fonts available. Would these characters all be part of the standard ASCII character set?

try running this -

DEFINE FILE SYSCOLUM
 CNTR/I9 WITH NAME = IF LAST CNTR EQ 0 THEN 32 ELSE LAST CNTR + 1 ;
 Cntr/I9 WITH NAME = CNTR - 32 ;
 Col/I9  WITH NAME = (Cntr / 30) + 1 ;
 Row/I9  WITH NAME = IMOD(Cntr, 30, 'I9') ;
END
TABLE FILE SYSCOLUM
   SUM CNTR
       COMPUTE
       CHAR/A1 = HEXBYT(CNTR, 'A1') ;
ACROSS Col	NOPRINT
BY Row		NOPRINT
WHERE RECORDLIMIT EQ 224
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS=CM, PAGESIZE='A4', LEFTMARGIN=0.635000, RIGHTMARGIN=0.635000,
    TOPMARGIN=0.635000, BOTTOMMARGIN=0.635000, SQUEEZE=ON,
    ORIENTATION=LANDSCAPE, $
TYPE=REPORT, GRID=OFF, FONT=TIMES NEW ROMAN, $
ENDSTYLE
END

If all the characters that you need appear, then it isn't a font issue. If there are some you need that don't appear, you'll need to add a custom font set to your installation as documented in the manuals.

Darin,

That's a great font-verification fex you created - I'm definitely putting it in my library.

The record-limit number should be 256, as there are 255 characters...

Thanks very much for this,

I'm not taking credit for that one. Somebody else wrote it and I found it very useful like Francis and just stuck it my library. I'm not exactly sure why it starts at character 32 but I think it's because those first characters were non-printable things like carriage return, form-feed, line feed, etc.

My apologies for not giving credit to the original author.

Searched for "character map" and it looks like that post originally came from Waz - Thanks again.

Doc: How to Configure Type 1 Postscript Fonts on the Windows and UNIX Platforms

I've upgraded the fex a bit, now printing the table for every font defined in C:\ibi\srv76\home\nls\pdf.fmp. I don't know what good this will do as I don't have a font that will display the Lithuanian characters. Also, using some fonts cause odd things to happen, you'll see if you run the fex.

-*== Test PDF Font list ========================================================

SET HOLDLIST=PRINTONLY
SET HOLDFORMAT=ALPHA
SET ASNAMES=ON
SET PAGE=NOLEAD
-RUN

-*== Retrieve list of Postscript fonts as defined in pdf.fmp =========
FILEDEF PDFFONTS DISK C:\ibi\srv76\home\nls\pdf.fmp
-RUN

FILEDEF MASTER DISK pdffonts.mas
-RUN

-WRITE MASTER FILENAME=PDFFONTS, SUFFIX=FIX, $
-WRITE MASTER SEGNAME=PDFFONTS, $
-WRITE MASTER FIELDNAME=PDFFONTS_LINE, FORMAT=A80, ACTUAL=A80, $
-WRITE MASTER DEFINE FONT_NAME_POSIT1/I4 = POSIT(PDFFONTS_LINE, 80, 'font=', 5, 'I4');
-WRITE MASTER DEFINE FONT_NAME_POSIT2/I4 = POSIT(PDFFONTS_LINE, 80, ',', 1, 'I4');
-WRITE MASTER DEFINE FONT_NAME/A50 = IF FONT_NAME_POSIT1 EQ 0  THEN '' ELSE 
-WRITE MASTER   SUBSTR(80, PDFFONTS_LINE, (FONT_NAME_POSIT1 + 5), (FONT_NAME_POSIT2 - 1), 50, 'A50');
-RUN

TABLE FILE PDFFONTS
SUM
FONT_NAME

BY FONT_NAME NOPRINT

WHERE FONT_NAME NE ''

ON TABLE HOLD AS HFONTS
END
-RUN

-*== Print font table for each font found in pdf.fmp =================
-READ HFONTS NOCLOSE &FONT_NAME.A50.

SET COMPOUND = OPEN
-RUN

-SET &FONT_CTR = 0;

-REPEAT END_REP1 WHILE &IORETURN EQ 0;

-TYPE &FONT_NAME

-SET &FONT_CTR = &FONT_CTR + 1;

DEFINE FILE SYSCOLUM
CNTR/I4 WITH NAME = IF LAST CNTR EQ 0 THEN 32 ELSE LAST CNTR + 1 ;
CNTR/I4 WITH NAME = CNTR - 32 ;
COL/I4  WITH NAME = (CNTR / 30) + 1 ;
ROW/I4  WITH NAME = IMOD(CNTR, 30, 'I4') ;
END

TABLE FILE SYSCOLUM
SUM
CNTR AS ''
COMPUTE CHAR/A1 = HEXBYT(CNTR, 'A1') ; AS ''

ACROSS COL NOPRINT
BY ROW     NOPRINT

WHERE RECORDLIMIT EQ 256

HEADING
"Font table for &FONT_NAME"

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
UNITS=IN, SQUEEZE=ON, PAGESIZE='Letter', ORIENTATION=LANDSCAPE,
LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=0.5, $
TYPE=REPORT, FONT='Arial', SIZE=14, TOPGAP=0.02, $
TYPE=REPORT, COLUMN=CNTR(*), COLOR=GRAY, FONT='Arial', $
TYPE=REPORT, COLUMN=CHAR(*), COLOR=BLACK, FONT='&FONT_NAME', RIGHTGAP=0.5, $
ENDSTYLE
END
-RUN

-READ HFONTS NOCLOSE &FONT_NAME.A50.

-END_REP1

SET COMPOUND = CLOSE
-RUN

TABLE FILE SYSCOLUM
PRINT NAME NOPRINT
WHERE READLIMIT EQ 1
ON TABLE SUBFOOT
"&FONT_CTR fonts printed"

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
UNITS=IN, SQUEEZE=ON, PAGESIZE='Letter', ORIENTATION=LANDSCAPE,
LEFTMARGIN=0.5, RIGHTMARGIN=0.5, TOPMARGIN=0.5, BOTTOMMARGIN=0.5, $
TYPE=REPORT, FONT='Arial', SIZE=14,$
ENDSTYLE
END
-RUN

Thanks Waz and Darin.

Well, we got a little off the topic here, but I tried Francis' code and for some reason it messes up all the fonts. For example it says its Arial but prints Garalt or says its OCRA but prints in Courier. If I run them individually, everything works fine, but not when run all together. Also noticed that the font pages toward the end turn up with the numbers in the specified font instead of the characters. Weird.

Thanks Darin, i really need to add new font because no font i have now give me the result i want.

How do i change/add new font so the letters show up? can you give a link or send me a email with that information? I can't find it somehow...

Thanks in advance.

derekas, please see the link I posted above, "How to Configure Type 1 Postscript Fonts on the Windows and UNIX Platforms"